Submissions for Ancient Lyric Poetry (ALyrA)
Description
This is version 1.0 of the ALyrA ontoterminology (i.e., 'a terminology whose conceptual system is a formal ontology', Roche 2007), which focuses on modelling Archaic Lyric poets (799-430 BCΕ). AlyrA stands for "Archaic Lyrical Agora". The ontoterminology was created by Rafail Giannadakis (Department of Philology, University of Crete) under the supervision of Dr. Maria Papadopoulou (Department of Philology, University of Crete). We gratefully acknowledge the generous funding of the European Commission in the context of the TALOS AI for SSH project (Grant agreement ID: 101087269).
8 of 8 submissions
#190
Natural Language Question
What is an “hymn” and which Archaic Lyric poets/poetesses have composed “hymns”?
SPARQL Query
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX alyra: <http://www.ontologia.fr/OTB/ALyrA_v.1.0#>
PREFIX otv: <http://www.ontologia.fr/OTB/otv#>
SELECT ?definition ?authorName ?centuryOfLiving
FROM <https://triplestore.talos-ai4ssh.uoc.gr:8890/datasets/Ancient-Lyric-Poetry-ALyrA-v1>
WHERE {
?x rdfs:label "hymn"@en.
?x skos:definition ?definition.
FILTER(langMatches(lang(?definition), "en"))
?y otv:instanceOf ?x;
alyra:isWrittenBy ?author.
?author rdfs:label ?authorName;
alyra:centuryOfLiving ?c.
?c rdfs:label ?centuryOfLiving.
}
ORDER BY ?centuryOfLiving
#191
Natural Language Question
Who was Pindar?
SPARQL Query
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX alyra: <http://www.ontologia.fr/OTB/ALyrA_v.1.0#>
SELECT ?propertyName ?value
FROM <https://triplestore.talos-ai4ssh.uoc.gr:8890/datasets/Ancient-Lyric-Poetry-ALyrA-v1>
WHERE {
alyra:pindarus_boeotus ?x ?y .
?x rdfs:label ?propertyName .
?y rdfs:label ?value .
FILTER(LANG(?value) = 'en')
}
ORDER BY ?value
#192
Natural Language Question
Which is the four-digit "Thesaurus Linguae Graecae" identifying number of each Archaic Lyric composer?
SPARQL Query
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX alyra: <http://www.ontologia.fr/OTB/ALyrA_v.1.0#>
PREFIX otv: <http://www.ontologia.fr/OTB/otv#>
SELECT ?nameOfComposer ?tljNumber
FROM <https://triplestore.talos-ai4ssh.uoc.gr:8890/datasets/Ancient-Lyric-Poetry-ALyrA-v1>
WHERE {
?x rdfs:subClassOf* alyra:Archaic_Lyric_Composer.
?y otv:instanceOf* ?x.
?y rdfs:label ?nameOfComposer;
alyra:tlgIdentifyingNumber ?tljNumber}
#193
Natural Language Question
What is the place where most Ancient Greek lyric composers were born and who were they?
SPARQL Query
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX otv: <http://www.ontologia.fr/OTB/otv#>
PREFIX alyra: <http://www.ontologia.fr/OTB/ALyrA_v.1.0#>
SELECT ?place ?coordinates ?poetLabel ?resourcePoet
FROM <https://triplestore.talos-ai4ssh.uoc.gr:8890/datasets/Ancient-Lyric-Poetry-ALyrA-v1>
WHERE {
{
SELECT ?place (COUNT(?y) AS ?count)
WHERE {
?x rdfs:subClassOf* alyra:Archaic_Lyric_Composer.
?y otv:instanceOf ?x.
?y alyra:bornIn ?p.
?p rdfs:label ?place.
}
GROUP BY ?place
ORDER BY DESC(?count)
LIMIT 1
}
?x rdfs:subClassOf* alyra:Archaic_Lyric_Composer.
?y otv:instanceOf ?x.
?y alyra:bornIn ?p.
?p rdfs:label ?place.
OPTIONAL { ?p alyra:pleiadesCoordinates ?coordinates. }
?y rdfs:label ?poetLabel.
OPTIONAL {
SELECT ?y (SAMPLE(?resource) AS ?resourcePoet)
WHERE {
?y rdfs:seeAlso ?resource.
FILTER(CONTAINS(LCASE(STR(?resource)), "perseus:author"))
}
GROUP BY ?y
}
}
ORDER BY ?poetLabel
#194
Natural Language Question
Which are the different Archaic Lyric poems and what differentiates each of them?
SPARQL Query
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX alyra: <http://www.ontologia.fr/OTB/ALyrA_v.1.0#>
PREFIX otv: <http://www.ontologia.fr/OTB/otv#>
SELECT ?poems ?difference ?definition
FROM <https://triplestore.talos-ai4ssh.uoc.gr:8890/datasets/Ancient-Lyric-Poetry-ALyrA-v1>
WHERE {
?x rdfs:subClassOf* alyra:Archaic_Lyric_Poem;
rdfs:label ?poems;
otv:ownDifference ?y;
skos:definition ?definition.
?y rdfs:label ?difference
FILTER (lang(?poems) = 'en')
FILTER (lang(?definition) = 'en')
}
#197
Natural Language Question
What are the different types of political crises?
Source
SPARQL Query
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX lac: <http://ontologia.fr/OTB/lac#>
SELECT DISTINCT ?crisisName
FROM <https://triplestore.talos-ai4ssh.uoc.gr:8890/datasets/LACRIMALit-Modeling-Events-Classical-Period-v1>
WHERE {
?crisis rdfs:subClassOf* lac:Political_Crisis.
?crisis rdfs:label ?crisisName.
FILTER (lang(?crisisName) = 'en')
}
ORDER BY ?crisisName
#198
Natural Language Question
Where did the sedition of Corfu take place?
Source
SPARQL Query
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX lac: <http://ontologia.fr/OTB/lac#>
SELECT DISTINCT ?locationName
FROM <https://triplestore.talos-ai4ssh.uoc.gr:8890/datasets/LACRIMALit-Modeling-Events-Classical-Period-v1>
WHERE {
?sedition rdf:type lac:Sedition;
rdfs:label ?seditionLabel;
lac:location ?location.
?location rdfs:label ?locationName.
# match label case-insensitively to avoid exact-case issues
FILTER(LANG(?locationName) = 'en')
FILTER(LANG(?seditionLabel) = 'en')
FILTER(LCASE(STR(?seditionLabel)) = LCASE("sedition of Corfu"))
}
#205
Natural Language Question
What are ancient lyric poetry types?
