Submissions for OpenCitations Meta

Description

OpenCitations Meta is a bibliographic metadata database for all publications referenced in the OpenCitations Index. It includes key metadata like titles, authors, publication dates, identifiers, publication venues, volume/issue/page numbers, and actors like editors and publishers, along with their persistent identifiers when available.

31 of 31 submissions
#31

Natural Language Question

What is the title and publication date of publication with DOI 10.1162/qss_a_00023?

SPARQL Query

Run Query 
    PREFIX datacite: <http://purl.org/spar/datacite/>
    PREFIX dcterms: <http://purl.org/dc/terms/>
    PREFIX literal: <http://www.essepuntato.it/2010/06/literalreification/>
    PREFIX prism: <http://prismstandard.org/namespaces/basic/2.0/>
    SELECT ?id ?title ?pub_date {
        ?identifier literal:hasLiteralValue "10.1162/qss_a_00023".
        ?br datacite:hasIdentifier ?identifier;
        dcterms:title ?title;
            prism:publicationDate ?publicationDate.
        BIND(STR(?publicationDate) AS ?pub_date)
        BIND((CONCAT("doi:", "10.1162/qss_a_00023")) AS ?id)
    }
#33

Natural Language Question

How many journal articles contained in Open Citations Meta were published in 2024?

SPARQL Query

Run Query 
PREFIX purlSF: <http://purl.org/spar/fabio/> 
PREFIX prismstandardNB2: <http://prismstandard.org/namespaces/basic/2.0/> 
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#> 

SELECT (COUNT(*) AS ?count) WHERE { 
  ?article a purlSF:JournalArticle . 
  ?article prismstandardNB2:publicationDate ?date . 
  FILTER(?date >= "2024-01-01"^^xsd:date && ?date <= "2024-12-31"^^xsd:date) 
}
#34

Natural Language Question

What are the titles and publication dates of book chapters written by authors whose family name is Singh?

SPARQL Query

Run Query 
PREFIX foaf: <http://xmlns.com/foaf/0.1/> 
PREFIX purlSF: <http://purl.org/spar/fabio/> 
PREFIX prismstandardNB2: <http://prismstandard.org/namespaces/basic/2.0/> 
PREFIX dcterms: <http://purl.org/dc/terms/> 
PREFIX purlSP: <http://purl.org/spar/pro/>

SELECT ?chapterTitle ?pubDate WHERE { 
      ?author a foaf:Agent ; 
              foaf:familyName "Singh" . 
      ?chapter a purlSF:BookChapter ; 
               dcterms:title ?chapterTitle ; 
               prismstandardNB2:publicationDate ?pubDate . 
      ?role purlSP:withRole purlSP:author ; 
            purlSP:forAgent ?author . 
      ?chapter purlSP:isDocumentContextFor ?role . 
}
#35

Natural Language Question

Quali sono le pubblicazioni dell'autore con ORCID 0000-0002-8420-0696 pubblicate nel 2024?

SPARQL Query

Run Query 
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX pro: <http://purl.org/spar/pro/>
PREFIX fabio: <http://purl.org/spar/fabio/>
PREFIX datacite: <http://purl.org/spar/datacite/>
PREFIX literal: <http://www.essepuntato.it/2010/06/literalreification/>
PREFIX prism: <http://prismstandard.org/namespaces/basic/2.0/>

SELECT ?publication ?title ?date
WHERE {
  ?agent datacite:hasIdentifier ?identifier .
  ?identifier datacite:usesIdentifierScheme datacite:orcid .
  {
    ?identifier literal:hasLiteralValue "0000-0002-8420-0696" .
  }
  UNION
  {
    ?identifier literal:hasLiteralValue "0000-0002-8420-0696"^^xsd:string .
  }
  ?role pro:isHeldBy ?agent ;
        pro:withRole pro:author .
  ?publication pro:isDocumentContextFor ?role ;
               dcterms:title ?title ;
               prism:publicationDate ?date .
  FILTER(YEAR(?date) = 2024)
}
#36

Natural Language Question

What are the latest 10 articles published in the journal with ISSN 2641-3337 (Quantitative Science Studies)?

SPARQL Query

Run Query 
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX fabio: <http://purl.org/spar/fabio/>
PREFIX frbr: <http://purl.org/vocab/frbr/core#>
PREFIX datacite: <http://purl.org/spar/datacite/>
PREFIX literal: <http://www.essepuntato.it/2010/06/literalreification/>
PREFIX prism: <http://prismstandard.org/namespaces/basic/2.0/>

SELECT ?article ?title ?date
WHERE {
  ?journal a fabio:Journal ;
           datacite:hasIdentifier ?identifier .
  ?identifier datacite:usesIdentifierScheme datacite:issn .
  {
    ?identifier literal:hasLiteralValue "2641-3337" .
  }
  UNION
  {
    ?identifier literal:hasLiteralValue "2641-3337"^^xsd:string .
  }
  ?volume frbr:partOf ?journal .
  ?issue frbr:partOf ?volume .
  ?article frbr:partOf ?issue ;
           a fabio:JournalArticle ;
           dcterms:title ?title ;
           prism:publicationDate ?date .
}
ORDER BY DESC(?date)
LIMIT 10
#37

Natural Language Question

What are the publications by the author with ORCID 0000-0003-0530-4305 published in 2024?

SPARQL Query

Run Query 
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX pro: <http://purl.org/spar/pro/>
PREFIX fabio: <http://purl.org/spar/fabio/>
PREFIX datacite: <http://purl.org/spar/datacite/>
PREFIX literal: <http://www.essepuntato.it/2010/06/literalreification/>
PREFIX prism: <http://prismstandard.org/namespaces/basic/2.0/>

SELECT ?publication ?title ?date
WHERE {
  ?agent datacite:hasIdentifier ?identifier .
  ?identifier datacite:usesIdentifierScheme datacite:orcid .
  {
    ?identifier literal:hasLiteralValue "0000-0003-0530-4305" .
  }
  UNION
  {
    ?identifier literal:hasLiteralValue "0000-0003-0530-4305"^^xsd:string .
  }
  ?role pro:isHeldBy ?agent ;
        pro:withRole pro:author .
  ?publication pro:isDocumentContextFor ?role ;
               dcterms:title ?title ;
               prism:publicationDate ?date .
  FILTER(YEAR(?date) = 2024)
}
#38

Natural Language Question

Which publications contain the words "open science" in the title and were published in 2024?

SPARQL Query

Run Query 
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX fabio: <http://purl.org/spar/fabio/>
PREFIX prism: <http://prismstandard.org/namespaces/basic/2.0/>
PREFIX bif: <http://www.openlinksw.com/schemas/bif#>

SELECT ?publication ?title ?date
WHERE {
  ?publication a fabio:Expression ;
               dcterms:title ?title ;
               prism:publicationDate ?date .
  FILTER(bif:contains(?title, '"open science"'))
  FILTER(CONTAINS(STR(?date), "2024"))
}
#39

Natural Language Question

Which books were published by "MIT Press" publisher in 2022?

SPARQL Query

Run Query 
PREFIX fabio: <http://purl.org/spar/fabio/>
PREFIX pro: <http://purl.org/spar/pro/>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX prism: <http://prismstandard.org/namespaces/basic/2.0/>
PREFIX bif: <http://www.openlinksw.com/schemas/bif#>

SELECT ?book ?title ?publisherName
WHERE {
  ?publisher foaf:name ?publisherName .
  ?publisherName bif:contains '"MIT Press"' .
  
  ?role pro:isHeldBy ?publisher ;
        pro:withRole pro:publisher .
  ?book pro:isDocumentContextFor ?role ;
        a fabio:Book ;
        dcterms:title ?title ;
        prism:publicationDate ?date .
  
  FILTER(CONTAINS(STR(?date), "2022"))
}
#40

Natural Language Question

Which articles published in 2023 in the journal "Scientometrics" have more than 10 pages?

SPARQL Query

Run Query 
PREFIX fabio: <http://purl.org/spar/fabio/>
PREFIX frbr: <http://purl.org/vocab/frbr/core#>
PREFIX prism: <http://prismstandard.org/namespaces/basic/2.0/>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX bif: <http://www.openlinksw.com/schemas/bif#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>

SELECT ?article ?articleTitle ?firstPage ?lastPage (xsd:integer(?lastPage) - xsd:integer(?firstPage) + 1 AS ?pageCount)
WHERE {
  ?journal dcterms:title ?journalTitle ;
           a fabio:Journal .
  ?journalTitle bif:contains '"Scientometrics"' .
  
  ?volume frbr:partOf ?journal .
  ?issue frbr:partOf ?volume .
  ?article frbr:partOf ?issue ;
           a fabio:JournalArticle ;
           dcterms:title ?articleTitle ;
           prism:publicationDate ?date ;
           frbr:embodiment ?embodiment .
  
  ?embodiment prism:startingPage ?firstPage ;
              prism:endingPage ?lastPage .
  
  FILTER(CONTAINS(STR(?date), "2023"))
  FILTER((xsd:integer(?lastPage) - xsd:integer(?firstPage) + 1) > 10)
}
#41

Natural Language Question

Which book chapters with "digital humanities" in their title were published in 2023?

SPARQL Query

Run Query 
PREFIX fabio: <http://purl.org/spar/fabio/>
PREFIX frbr: <http://purl.org/vocab/frbr/core#>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX prism: <http://prismstandard.org/namespaces/basic/2.0/>
PREFIX bif: <http://www.openlinksw.com/schemas/bif#>

SELECT ?chapter ?chapterTitle ?bookTitle
WHERE {
  ?chapter a fabio:BookChapter ;
           dcterms:title ?chapterTitle ;
           prism:publicationDate ?chapterDate ;
           frbr:partOf ?book .
  ?chapterTitle bif:contains '"digital humanities"' .
  
  ?book a fabio:Book ;
        dcterms:title ?bookTitle .
  
  FILTER(CONTAINS(STR(?chapterDate), "2023"))
}
#42

Natural Language Question

Which publications were co-authored by Silvio Peroni and Fabio Vitali?

SPARQL Query

Run Query 
PREFIX pro: <http://purl.org/spar/pro/>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX prism: <http://prismstandard.org/namespaces/basic/2.0/>

SELECT DISTINCT ?publication ?title ?date
WHERE {
  ?agent1 foaf:givenName "Silvio" ;
          foaf:familyName "Peroni" .
  
  ?agent2 foaf:givenName "Fabio" ;
          foaf:familyName "Vitali" .
  
  ?role1 pro:isHeldBy ?agent1 ;
         pro:withRole pro:author .
  ?role2 pro:isHeldBy ?agent2 ;
         pro:withRole pro:author .
         
  ?publication pro:isDocumentContextFor ?role1 ;
               pro:isDocumentContextFor ?role2 ;
               dcterms:title ?title ;
               prism:publicationDate ?date .
}
ORDER BY DESC(?date)
#43

Natural Language Question

Which proceedings papers have "semantic web" in their title?

SPARQL Query

Run Query 
PREFIX fabio: <http://purl.org/spar/fabio/>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX prism: <http://prismstandard.org/namespaces/basic/2.0/>
PREFIX bif: <http://www.openlinksw.com/schemas/bif#>

SELECT ?paper ?paperTitle ?date
WHERE {
  ?paper a fabio:ProceedingsPaper ;
         dcterms:title ?paperTitle .
  ?paperTitle bif:contains '"semantic web"' .
  
  OPTIONAL { ?paper prism:publicationDate ?date }
}
#44

Natural Language Question

Which articles about "COVID-19" published in 2023 have more than 5 authors?

SPARQL Query

Run Query 
PREFIX fabio: <http://purl.org/spar/fabio/>
PREFIX pro: <http://purl.org/spar/pro/>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX prism: <http://prismstandard.org/namespaces/basic/2.0/>
PREFIX bif: <http://www.openlinksw.com/schemas/bif#>

SELECT ?article ?title (COUNT(DISTINCT ?author) as ?authorCount)
WHERE {
  ?article a fabio:JournalArticle ;
           dcterms:title ?title ;
           prism:publicationDate ?date ;
           pro:isDocumentContextFor ?role .
  ?title bif:contains '"COVID-19"' .
  
  ?role pro:withRole pro:author ;
        pro:isHeldBy ?author .
  
  FILTER(CONTAINS(STR(?date), "2023"))
}
GROUP BY ?article ?title
HAVING (COUNT(DISTINCT ?author) > 5)
ORDER BY DESC(?authorCount)
#45

Natural Language Question

Which papers with "cancer" in the title published after 2023 have a PubMed ID?

SPARQL Query

Run Query 
PREFIX fabio: <http://purl.org/spar/fabio/>
PREFIX datacite: <http://purl.org/spar/datacite/>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX prism: <http://prismstandard.org/namespaces/basic/2.0/>
PREFIX literal: <http://www.essepuntato.it/2010/06/literalreification/>
PREFIX bif: <http://www.openlinksw.com/schemas/bif#>

SELECT DISTINCT ?article ?title ?pmid ?date
WHERE {
  ?article dcterms:title ?title ;
           a fabio:JournalArticle ;
           prism:publicationDate ?date ;
           datacite:hasIdentifier ?id .
  ?title bif:contains '"cancer"' .
  
  ?id datacite:usesIdentifierScheme datacite:pmid ;
      literal:hasLiteralValue ?pmid .
  
  FILTER(STR(?date) > "2023")
}
#46

Natural Language Question

Which books with "artificial intelligence" in the title were published by university presses after 2022?

SPARQL Query

Run Query 
PREFIX fabio: <http://purl.org/spar/fabio/>
PREFIX pro: <http://purl.org/spar/pro/>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX prism: <http://prismstandard.org/namespaces/basic/2.0/>
PREFIX bif: <http://www.openlinksw.com/schemas/bif#>

SELECT ?book ?title ?publisherName
WHERE {
  ?book dcterms:title ?title ;
        a fabio:Book ;
        prism:publicationDate ?date ;
        pro:isDocumentContextFor ?role .
  ?title bif:contains '"artificial intelligence"' .
  
  ?role pro:withRole pro:publisher ;
        pro:isHeldBy ?publisher .
  ?publisher foaf:name ?publisherName .
  ?publisherName bif:contains '"University Press"' .
  
  FILTER(STR(?date) > "2022")
}
#47

Natural Language Question

Which articles did the authors with family name "Zhang" publish in the journal with ISSN 0028-0836 (Nature)?

SPARQL Query

Run Query 
PREFIX fabio: <http://purl.org/spar/fabio/>
PREFIX frbr: <http://purl.org/vocab/frbr/core#>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX pro: <http://purl.org/spar/pro/>
PREFIX datacite: <http://purl.org/spar/datacite/>
PREFIX literal: <http://www.essepuntato.it/2010/06/literalreification/>
PREFIX dcterms: <http://purl.org/dc/terms/>

SELECT ?article ?title ?authorName
WHERE {
  ?journal a fabio:Journal ;
           datacite:hasIdentifier ?identifier .
  ?identifier datacite:usesIdentifierScheme datacite:issn .
  {
    ?identifier literal:hasLiteralValue "0028-0836" .
  }
  UNION
  {
    ?identifier literal:hasLiteralValue "0028-0836"^^xsd:string .
  }
  
  ?volume frbr:partOf ?journal .
  ?issue frbr:partOf ?volume .
  ?article frbr:partOf ?issue ;
           a fabio:JournalArticle ;
           dcterms:title ?title ;
           pro:isDocumentContextFor ?role .
  
  ?role pro:withRole pro:author ;
        pro:isHeldBy ?author .
  ?author foaf:familyName "Zhang" ;
          foaf:name ?authorName .
}
#48

Natural Language Question

Which papers mention "European" in their title and were published in 2023?

SPARQL Query

Run Query 
PREFIX fabio: <http://purl.org/spar/fabio/>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX prism: <http://prismstandard.org/namespaces/basic/2.0/>
PREFIX bif: <http://www.openlinksw.com/schemas/bif#>

SELECT ?paper ?title ?date
WHERE {
  ?paper dcterms:title ?title ;
         a fabio:Expression ;
         prism:publicationDate ?date .
  ?title bif:contains '"European"' .
  
  FILTER(CONTAINS(STR(?date), "2023"))
}
#49

Natural Language Question

Which books have "climate change" in their title?

SPARQL Query

Run Query 
PREFIX fabio: <http://purl.org/spar/fabio/>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX prism: <http://prismstandard.org/namespaces/basic/2.0/>
PREFIX bif: <http://www.openlinksw.com/schemas/bif#>

SELECT ?book ?title ?date
WHERE {
  ?book dcterms:title ?title ;
             a fabio:Book .
  ?title bif:contains '"climate change"' .
  
  OPTIONAL { ?book prism:publicationDate ?date }
}
#50

Natural Language Question

Which papers in journals with "Computer" in their title have between 8 and 12 pages?

SPARQL Query

Run Query 
PREFIX fabio: <http://purl.org/spar/fabio/>
PREFIX frbr: <http://purl.org/vocab/frbr/core#>
PREFIX prism: <http://prismstandard.org/namespaces/basic/2.0/>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX bif: <http://www.openlinksw.com/schemas/bif#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>

SELECT ?article ?articleTitle ?journalTitle ?pageCount
WHERE {
  ?journal dcterms:title ?journalTitle ;
           a fabio:Journal .
  ?journalTitle bif:contains '"Computer"' .
  
  ?volume frbr:partOf ?journal .
  ?issue frbr:partOf ?volume .
  ?article frbr:partOf ?issue ;
           a fabio:JournalArticle ;
           dcterms:title ?articleTitle ;
           frbr:embodiment ?embodiment .
  
  ?embodiment prism:startingPage ?firstPage ;
              prism:endingPage ?lastPage .
  
  BIND(xsd:integer(?lastPage) - xsd:integer(?firstPage) + 1 AS ?pageCount)
  FILTER(?pageCount >= 8 && ?pageCount <= 12)
}
#51

Natural Language Question

Which papers by Matteo Romanello (ORCID 0000-0002-7406-6286) were published in 2022?

SPARQL Query

Run Query 
PREFIX pro: <http://purl.org/spar/pro/>
PREFIX datacite: <http://purl.org/spar/datacite/>
PREFIX literal: <http://www.essepuntato.it/2010/06/literalreification/>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX prism: <http://prismstandard.org/namespaces/basic/2.0/>

SELECT ?publication ?title ?date
WHERE {
  ?agent datacite:hasIdentifier ?identifier .
  ?identifier datacite:usesIdentifierScheme datacite:orcid .
  {
    ?identifier literal:hasLiteralValue "0000-0002-7406-6286" .
  }
  UNION
  {
    ?identifier literal:hasLiteralValue "0000-0002-7406-6286"^^xsd:string .
  }
  
  ?role pro:isHeldBy ?agent ;
        pro:withRole pro:author .
  ?publication pro:isDocumentContextFor ?role ;
               dcterms:title ?title ;
               prism:publicationDate ?date .
  
  FILTER(CONTAINS(STR(?date), "2022"))
}
#52

Natural Language Question

Which theses have "machine learning" in their title?

SPARQL Query

Run Query 
PREFIX fabio: <http://purl.org/spar/fabio/>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX prism: <http://prismstandard.org/namespaces/basic/2.0/>
PREFIX bif: <http://www.openlinksw.com/schemas/bif#>

SELECT ?thesis ?title ?date
WHERE {
  ?thesis dcterms:title ?title .
  ?title bif:contains '"machine learning"' .
  ?thesis a fabio:Thesis .
  
  OPTIONAL { ?thesis prism:publicationDate ?date }
}
#53

Natural Language Question

Which books have "Egypt" or "Egyptian" in their title?

SPARQL Query

Run Query 
PREFIX fabio: <http://purl.org/spar/fabio/>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX prism: <http://prismstandard.org/namespaces/basic/2.0/>
PREFIX bif: <http://www.openlinksw.com/schemas/bif#>

SELECT ?paper ?title ?date
WHERE {
  ?paper dcterms:title ?title ;
         a fabio:Book .
  ?title bif:contains '"Egypt"' .
  
  OPTIONAL { ?paper prism:publicationDate ?date }
}
#54

Natural Language Question

Which papers mention "Book of Caverns" in their title?

SPARQL Query

Run Query 
PREFIX fabio: <http://purl.org/spar/fabio/>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX prism: <http://prismstandard.org/namespaces/basic/2.0/>
PREFIX bif: <http://www.openlinksw.com/schemas/bif#>

SELECT ?paper ?title ?date
WHERE {
  ?paper dcterms:title ?title ;
         a fabio:Expression .
  ?title bif:contains '"Book of Caverns"' .
  
  OPTIONAL { ?paper prism:publicationDate ?date }
}
#55

Natural Language Question

Which papers mention "Amduat" in their title?

SPARQL Query

Run Query 
PREFIX fabio: <http://purl.org/spar/fabio/>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX prism: <http://prismstandard.org/namespaces/basic/2.0/>
PREFIX bif: <http://www.openlinksw.com/schemas/bif#>

SELECT ?paper ?title ?date
WHERE {
  ?paper dcterms:title ?title ;
         a fabio:Expression .
  ?title bif:contains '"Amduat"' .
  
  OPTIONAL { ?paper prism:publicationDate ?date }
}
#70

Natural Language Question

How many research papers in the OpenCitations knowledge graph cover the topic of ethnomusiciology?
#72

Natural Language Question

What is the definition of interdisciplinarity?
#73

Natural Language Question

What are the most cited books published in 2010?
#78

Natural Language Question

List 10 the most cited journals indexed as social sciences journals
#81

Natural Language Question

List 10 the most cited journals indexed as social sciences journals.
#84

Natural Language Question

What are the journal articles published after 2022 that contains the term "AI" in their title?

Source

https://www.unibo.it/sitoweb/marta.soricetti2

SPARQL Query

Run Query 
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX prism: <http://prismstandard.org/namespaces/basic/2.0/>
PREFIX fabio: <http://purl.org/spar/fabio/>
PREFIX bif: <http://www.openlinksw.com/schemas/bif#>
SELECT ?journalArticle ?title ?date {
    ?br a fabio:JournalArticle ;
       	dcterms:title ?title;
        prism:publicationDate ?date.
  	?title bif:contains '"AI"' .
    FILTER(STR(?date) > "2022")
}
#88

Natural Language Question

how many journal articles in OCM were published in 2024?
Back to Browse
Odoma and Graphia logos

Quagga has been developed by Odoma ↗ for Graphia ↗

Funded by the European Union (grant ID: 1O1188018 ↗)

Contact Github FAQ