Submissions for DNB KB

Description

The DNB Knowledge Graph at https://sparql.dnb.de/dnbgnd is a linked-data service from the German National Library (Deutsche Nationalbibliothek) that unifies GND authority data (Gemeinsame Normdatei) with national bibliography metadata in a semantically rich RDF graph. It lets users perform SPARQL queries over interconnected entities—such as people, works, subjects, and bibliographic records—linking normative identifiers with bibliographic information to support complex discovery and analysis. All data are published as open linked data, enabling integration with the wider semantic web and bibliographic ecosystems.

Learn more about this knowledge graph
Access the SPARQL endpoint
Download metadata

12 of 12 submissions

#135

Natural Language Question

Which authors published in Berlin in the 19th century?

Source

https://sparql.dnb.de/dnbgnd/rINlrT

SPARQL Query

Run Query

PREFIX gndo: <https://d-nb.info/standards/elementset/gnd#>
PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX gnd: <https://d-nb.info/gnd/>
PREFIX rdau: <http://rdaregistry.info/Elements/u/>
PREFIX wdrs: <http://www.w3.org/2007/05/powder-s#> 
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX bibo: <http://purl.org/ontology/bibo/>
PREFIX rdact: <http://rdaregistry.info/termList/RDACarrierType/>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX marcRole: <http://id.loc.gov/vocabulary/relators/>
PREFIX schema: <http://schema.org/>

SELECT DISTINCT ?author ?name  WHERE { 
?work marcRole:pbl ?pub ; dct:issued ?year .
FILTER ( bound(?year) && xsd:integer(?year) >= 1800 && xsd:integer(?year) < 1900 ) .
?pub gndo:placeOfBusiness <https://d-nb.info/gnd/4005728-8> .
?work dct:creator ?author .
?author gndo:preferredNameForThePerson ?name . 
OPTIONAL {
    ?pub schema:location "Berlin" .
  } 
}

#222

Natural Language Question

Which authors are known for featuring “Italy” in their works?

Source

https://sparql.dnb.de/dnbgnd

SPARQL Query

Run Query

PREFIX gndo: <https://d-nb.info/standards/elementset/gnd#>
PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX gnd: <https://d-nb.info/gnd/>
SELECT distinct ?creator ?name WHERE {
  ?gnd gndo:geographicAreaCode <https://d-nb.info/standards/vocab/gnd/geographic-area-code#XA-IT> .
  ?work dcterms:subject ?gnd .
  ?work dcterms:creator ?creator .
  ?creator gndo:preferredNameForThePerson ?name .
  }

#223

Natural Language Question

How many works by a specific GND person (e.g., Hannah Arendt) are found in the DNB knowledge graph?

Source

https://sparql.dnb.de/dnbgnd

SPARQL Query

Run Query

PREFIX gndo: <https://d-nb.info/standards/elementset/gnd#>
PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX gnd: <https://d-nb.info/gnd/>
PREFIX rdau: <http://rdaregistry.info/Elements/u/>
PREFIX wdrs: <http://www.w3.org/2007/05/powder-s#> 
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX bibo: <http://purl.org/ontology/bibo/>
PREFIX rdact: <http://rdaregistry.info/termList/RDACarrierType/>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX marcRole: <http://id.loc.gov/vocabulary/relators/>
PREFIX schema: <http://schema.org/>

SELECT (COUNT(?work) AS ?Anzahl) WHERE {
?work dct:creator <https://d-nb.info/gnd/11850391X> . # Hannah Arendt
}

#224

Natural Language Question

How has the frequency of the keyword “feminism” changed since 1900?

Source

https://sparql.dnb.de/dnbgnd

SPARQL Query

Run Query

PREFIX gndo: <https://d-nb.info/standards/elementset/gnd#>
PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX gnd: <https://d-nb.info/gnd/>
PREFIX rdau: <http://rdaregistry.info/Elements/u/>
PREFIX wdrs: <http://www.w3.org/2007/05/powder-s#>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX bibo: <http://purl.org/ontology/bibo/>
PREFIX rdact: <http://rdaregistry.info/termList/RDACarrierType/>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>

SELECT (?year_sub AS ?Jahr) (COUNT(?work) AS ?Anzahl) WHERE {
  ?work dct:subject <https://d-nb.info/gnd/4222126-2> ; # Schlagwort "Feminismus"
        dct:issued ?year .
		BIND( SUBSTR( STR(?year), 1, 4 )  AS ?year_sub ) # Vereinheitlichung der Jahreszahl YYYY
		FILTER ( bound(?year_sub) && xsd:integer(?year_sub) >= 1900) .
		
}
GROUP BY ?year_sub
ORDER BY ?Jahr

#225

Natural Language Question

Which works bring together the concepts of “art history” and “digital humanities”?

Source

https://sparql.dnb.de/dnbgnd

SPARQL Query

Run Query

PREFIX gndo: <https://d-nb.info/standards/elementset/gnd#>
PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX gnd: <https://d-nb.info/gnd/>
PREFIX rdau: <http://rdaregistry.info/Elements/u/>
PREFIX wdrs: <http://www.w3.org/2007/05/powder-s#>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX bibo: <http://purl.org/ontology/bibo/>
PREFIX rdact: <http://rdaregistry.info/termList/RDACarrierType/>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>

SELECT ?work ?title WHERE {
  ?work dc:title ?title ;
        dct:subject <https://d-nb.info/gnd/4138803-3> ; # Kunstgeschichte
        dct:subject <https://d-nb.info/gnd/1038714850> . # Digital Humanities
}

#226

Natural Language Question

Which keywords are most frequently used in documents about antisemitism?

Source

https://sparql.dnb.de/dnbgnd/zEryCg

SPARQL Query

Run Query

PREFIX gndo: <https://d-nb.info/standards/elementset/gnd#>
PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX gnd: <https://d-nb.info/gnd/>
PREFIX rdau: <http://rdaregistry.info/Elements/u/>
PREFIX wdrs: <http://www.w3.org/2007/05/powder-s#>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX bibo: <http://purl.org/ontology/bibo/>
PREFIX rdact: <http://rdaregistry.info/termList/RDACarrierType/>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>

SELECT ?subject ?sw_name (COUNT(?work) AS ?Häufigkeit) WHERE {
  ?work dct:subject <https://d-nb.info/gnd/4002333-3> ;
        dct:subject ?subject .
		FILTER (?subject != <https://d-nb.info/gnd/4002333-3>)
  ?subject gndo:preferredNameForTheSubjectHeading ?sw_name .
  
  OPTIONAL {
     ?subject gndo:preferredNameForThePlaceOrGeographicName ?sw_name .
  }
  OPTIONAL {
	 ?subject gndo:preferredNameForThePerson ?sw_name .
  }
 
}
GROUP BY ?subject ?sw_name 
ORDER BY DESC(?Häufigkeit)
LIMIT 20

#227

Natural Language Question

What is the gender distribution among authors of works tagged with “colonialism”?

Source

https://sparql.dnb.de/dnbgnd/AuUaU1

SPARQL Query

Run Query

PREFIX gndo: <https://d-nb.info/standards/elementset/gnd#>
PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX gnd: <https://d-nb.info/gnd/>
PREFIX rdau: <http://rdaregistry.info/Elements/u/>
PREFIX wdrs: <http://www.w3.org/2007/05/powder-s#>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX bibo: <http://purl.org/ontology/bibo/>
PREFIX rdact: <http://rdaregistry.info/termList/RDACarrierType/>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX marcRole: <http://id.loc.gov/vocabulary/relators/>
PREFIX schema: <http://schema.org/>

SELECT ?gender (COUNT(?author) AS ?Anzahl) WHERE {
  ?work dct:subject <https://d-nb.info/gnd/4073624-6> ; # Schlagwort Kolonialismus
        dct:creator ?author .
  ?author gndo:gender ?gender .
}
GROUP BY ?gender

#228

Natural Language Question

How many titles have been published in languages other than German?

Source

https://sparql.dnb.de/dnbgnd/cod3qw

SPARQL Query

Run Query

PREFIX gndo: <https://d-nb.info/standards/elementset/gnd#>
PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX gnd: <https://d-nb.info/gnd/>
PREFIX rdau: <http://rdaregistry.info/Elements/u/>
PREFIX wdrs: <http://www.w3.org/2007/05/powder-s#>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX bibo: <http://purl.org/ontology/bibo/>
PREFIX rdact: <http://rdaregistry.info/termList/RDACarrierType/>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX marcRole: <http://id.loc.gov/vocabulary/relators/>
PREFIX schema: <http://schema.org/>

SELECT ?lang (COUNT(?work) AS ?Anzahl) WHERE {
  ?work dct:language ?lang .
  FILTER (?lang != <http://id.loc.gov/vocabulary/iso639-2/ger>)
}
GROUP BY ?lang
ORDER BY DESC(?Anzahl)

#229

Natural Language Question

How is the production of children’s and young adult books distributed geographically?

Source

https://sparql.dnb.de/dnbgnd/f8qKKx

SPARQL Query

Run Query

PREFIX gndo: <https://d-nb.info/standards/elementset/gnd#>
PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX gnd: <https://d-nb.info/gnd/>
PREFIX rdau: <http://rdaregistry.info/Elements/u/>
PREFIX wdrs: <http://www.w3.org/2007/05/powder-s#>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX bibo: <http://purl.org/ontology/bibo/>
PREFIX rdact: <http://rdaregistry.info/termList/RDACarrierType/>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX marcRole: <http://id.loc.gov/vocabulary/relators/>
PREFIX schema: <http://schema.org/>
PREFIX dnbt: <https://d-nb.info/standards/elementset/dnb#> 

SELECT ?area ?name (COUNT(?work) AS ?Anzahl) WHERE {
  ?work dc:subject "K"^^dnbt:ddc-subject-category ;
        marcRole:pbl ?pub .
  ?pub gndo:spatialAreaOfActivity ?area .
  ?area gndo:preferredNameForThePlaceOrGeographicName ?name .
}
GROUP BY ?area ?name 
ORDER BY DESC(?Anzahl)

#230

Natural Language Question

What are the titles of books published by philosophers on “AI” since 2010?

Source

https://sparql.dnb.de/dnbgnd/cod3qw

SPARQL Query

Run Query

PREFIX gndo: <https://d-nb.info/standards/elementset/gnd#>
PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
SELECT ?work ?title ?date ?authorName ?gender ?job WHERE {
  ?work dc:title ?title ;
        dct:issued ?date ;
        dct:creator ?author ;
        dct:subject <https://d-nb.info/gnd/4033447-8> . # KI 
  ?author gndo:gender ?gender ;
          gndo:preferredNameForThePerson ?authorName
  FILTER (bound(?date) && xsd:integer(?date) > 2010)
  ?author gndo:professionOrOccupation ?jobnode .
  ?jobnode (rdf:_1|rdf:_2|rdf:_3|rdf:_4|rdf:_5|rdf:_6|rdf:_7|rdf:_8) ?job .
  FILTER (?job = <https://d-nb.info/gnd/4174285-0> || ?job = <https://d-nb.info/gnd/4045790-4>) # Philosophin oder Philosoph
  
}
ORDER BY ASC(?authorName)

#231

Natural Language Question

Which works by other authors belong to the same literary movement as Friedrich Schiller?

Source

https://sparql.dnb.de/dnbgnd/3nlwn8

SPARQL Query

Run Query

PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX dbc: <http://dbpedia.org/resource/Category:>
PREFIX dbo: <http://dbpedia.org/ontology/>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX dcterms: <http://purl.org/dc/terms/>  
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX gndo: <https://d-nb.info/standards/elementset/gnd#>
PREFIX dc: <http://purl.org/dc/elements/1.1/>
  
SELECT DISTINCT ?title ?dnbitem ?otherAuthors ?otherAuthorsId   WHERE { 
    SERVICE <https://dbpedia.org/sparql> { # Federated Query dbpedia
      ?s rdfs:label "Friedrich Schiller"@de .
      ?s dbo:movement ?movement .
      ?other dbo:movement ?othermovement .
      ?other owl:sameAs ?otherAuthorsId .
      ?other rdfs:label ?otherAuthors FILTER (LANG(?otherAuthors)="de") .
      FILTER regex(?otherAuthorsId, "^http://viaf", "i")
      FILTER ((?movement = ?othermovement) && (?other != ?s))
   }
      
   ?dnbitem dc:title ?title ;
      dcterms:creator ?creator .
   ?creator owl:sameAs ?otherAuthorsId .
}

#232

Natural Language Question

What are the publications by authors with connections to Italy who have a biographical entry containing the keyword “Digital Humanities”?

Source

https://sparql.dnb.de/dnbgnd/Ec2wUN

SPARQL Query

Run Query

PREFIX gndo: <https://d-nb.info/standards/elementset/gnd#>
PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX dcterms: <http://purl.org/dc/terms/>
SELECT ?person ?name ?work ?title WHERE {
  ?person a gndo:DifferentiatedPerson ;
         gndo:geographicAreaCode <https://d-nb.info/standards/vocab/gnd/geographic-area-code#XA-IT> ;
		 gndo:biographicalOrHistoricalInformation ?bio ;
		 gndo:preferredNameForThePerson ?name .
  FILTER (CONTAINS(?bio,"Digital Humanities") ) 
  ?work dcterms:creator ?person ;
        dc:title ?title .
}
LIMIT 10

Quagga has been developed by Odoma ↗ for Graphia ↗

Funded by the European Union (grant ID: 101188018 ↗)

and by the Swiss State Secretariat for Education, Research and Innovation (SERI).

Contact Github FAQ