Submissions for Wikidata

Description

Wikidata is a free and open knowledge base that can be read and edited by both humans and machines. Wikidata acts as central storage for the structured data of its Wikimedia sister projects including Wikipedia, Wikivoyage, Wiktionary, Wikisource, and others.

Learn more about this knowledge graph
Access the SPARQL endpoint
Download metadata

9 of 9 submissions

#265

Natural Language Question

What is the population of the United States?

#268

Natural Language Question

quels acteurs ont interprété Hamlet au 20è siècle ?

#279

Natural Language Question

Which archaeological artifacts are on WikiProject IDEA's focus list, where were they discovered, and in which collections are they kept? Include the coordinates of the discovery sites and collections, and display only English labels for artifacts and collections.

Source

SPARQL Query

Run Query

PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX bd: <http://www.bigdata.com/rdf#>
PREFIX wikibase: <http://wikiba.se/ontology#>

#defaultView:Table
SELECT ?artifact ?artifactLabel ?discoveryLocation ?discoveryLocationLabel ?discoveryCoord ?collection ?collectionLabel ?collectionCoord
WHERE {
  {
    SELECT ?artifact (SAMPLE(?loc) AS ?discoveryLocation) (SAMPLE(?col) AS ?collection)
    WHERE {
      # 1. Filter for items on the focus list of WikiProject IDEA
      ?artifact wdt:P5008 wd:Q114241199 .
      
      # 2. Filter for items that are instances/subclasses of archaeological artifact
      ?artifact wdt:P31/wdt:P279* wd:Q220659 .
      
      # 3. Get the location of discovery
      ?artifact wdt:P189 ?loc .
      
      # 4. Get the collection
      ?artifact wdt:P195 ?col .
      
      # Filter out broader parent locations if a more granular sub-location exists via "Part of" (P361)
      # (e.g., If 'Room H' is part of 'Palmyrene Gate', drop 'Palmyrene Gate')
      FILTER NOT EXISTS {
        ?artifact wdt:P189 ?broaderLoc .
        FILTER(?broaderLoc != ?loc)
        ?loc wdt:P361+ ?broaderLoc .
      }
    }
    GROUP BY ?artifact
  }
  
  # Fetch coordinate locations for the finalized unique pairs
  OPTIONAL { ?discoveryLocation wdt:P625 ?discoveryCoord . }
  OPTIONAL { ?collection wdt:P625 ?collectionCoord . }
  
  # Fetch human-readable labels for the variables
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

#280

Natural Language Question

Which inscriptions were discovered at Dura-Europos? For each, show its language, the precise location where it was found and its coordinates, and a picture if one exists.

SPARQL Query

Run Query

      
#defaultView:Table
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX bd: <http://www.bigdata.com/rdf#>

SELECT DISTINCT ?languageLabel ?inscription ?inscriptionLabel ?findspot ?findspotLabel ?coordinate ?image WHERE {
  ?inscription wdt:P31/wdt:P279* wd:Q1640824 ;  # inscription or subclass of inscription
               wdt:P189 wd:Q464266 .           # found at Dura-Europos

  OPTIONAL {
    ?inscription wdt:P407 ?language .           # language of work/name
  }

  OPTIONAL {
    ?inscription wdt:P189 ?findspot .
    FILTER(?findspot != wd:Q464266)             # exclude generic Dura-Europos value
    OPTIONAL {
      ?findspot wdt:P625 ?coordinate .
    }
  }

  OPTIONAL {
    ?inscription wdt:P18 ?image .
  }

  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en" .
  }
}
ORDER BY ?languageLabel ?inscriptionLabel ?findspotLabel

#300

Natural Language Question

Which temples found in the site of Doura Europos are dedicated to which deities? I’d like to get the detailed count by deity.

Source

https://pelagios.org/

SPARQL Query

Run Query

PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT ?deity ?deityLabel (COUNT(DISTINCT ?temple) AS ?templeCount) WHERE {
  VALUES ?loc { wdt:P276 wdt:P131 }
  ?temple ?loc wd:Q464266 .
  ?temple wdt:P31 wd:Q44539 .
  ?temple wdt:P825 ?deity .
  FILTER(STRSTARTS(STR(?deity), "http://www.wikidata.org/entity/Q"))
  ?deity rdfs:label ?deityLabel . FILTER(LANG(?deityLabel) = "en")
}
GROUP BY ?deity ?deityLabel
ORDER BY DESC(?templeCount)

#306

Natural Language Question

Where were fibulae found at Dura-Europos discovered; what are their specific findspots, and what do they look like?

Source

https://pelagios.org/

SPARQL Query

Run Query

PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX bd: <http://www.bigdata.com/rdf#>
PREFIX wikibase: <http://wikiba.se/ontology#>

#defaultView:Map
SELECT ?object ?objectLabel ?place ?coordinate ?image WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?object wdt:P31 wd:Q324926. #object is an instance of ‘fibula’
  ?object wdt:P189 wd:Q464266, ?place. #show ?object that has a location of discovery Dura-Europos and store the value for ?place variable
  ?place wdt:P625 ?coordinate. #find the ?place variable's coordinate value
  OPTIONAL { ?object wdt:P18 ?image. } #if ?object has an image, show the image file
}

#308

Natural Language Question

Where were inscriptions found at Dura-Europos discovered, and what are their specific findspots?

Source

https://pelagios.org/

SPARQL Query

Run Query

PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX bd: <http://www.bigdata.com/rdf#>
PREFIX wikibase: <http://wikiba.se/ontology#>

#defaultView:Map
SELECT ?object ?objectLabel ?place ?coordinate ?image WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?object wdt:P31 wd:Q1640824. #object is instance of 'inscription'
  ?object wdt:P189 wd:Q464266, ?place. #show ?object that has a location of discovery Dura-Europos and store the value for ?place variable
  ?place wdt:P625 ?coordinate. #find the ?place variable's coordinate value
  OPTIONAL { ?object wdt:P18 ?image. } #if ?object has an image, show the image file
}

#309

Natural Language Question

Which divinities were worshipped at temples in Dura-Europos, and where else were temples dedicated to those same divinities located?

Source

https://pelagios.org/

SPARQL Query

Run Query

PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX bd: <http://www.bigdata.com/rdf#>

SELECT ?temple ?templeLabel ?divinity ?divinityLabel ?coords WHERE {
  # First, find the divinities with temples dedicated to them at Dura-Europos
  VALUES ?divinity { 
    # Insert the IDs of the divinities you got from part 1 here, for example:
    wd:Q99743232 wd:Q99743300 wd:Q34201 wd:Q1640824 wd:Q213440 wd:Q1243867 wd:Q1302646 wd:Q37340 wd:Q163920 wd:Q221735 wd:Q39503 wd:Q1809764 wd:Q99743301 wd:Q890208 wd:Q86664835 wd:Q2894617 
  }
  
  # Find all temples associated with these divinities
  ?temple wdt:P31 wd:Q44539.  # instance of temple
  ?temple wdt:P825 ?divinity;  # associated with the divinity
          wdt:P625 ?coords.  # get coordinates for these temples

  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

#310

Natural Language Question

Among items on the Wikiproject IDEA focus list that were discovered at Dura-Europos, which ones depict a deity, and what are their findspot coordinates, holding collections, and images?

Source

https://pelagios.org/

SPARQL Query

Run Query

PREFIX wd: <http://www.wikidata.org/entity/> 
PREFIX wdt: <http://www.wikidata.org/prop/direct/> 
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#> #defaultView:Map 
SELECT DISTINCT ?item ?itemLabel ?depictsLabel ?collectionLabel ?siteCoord ?image 
WHERE {
  ?item wdt:P5008 wd:Q114241199 .
   ?item wdt:P189 wd:Q464266 .
   ?item wdt:P180 ?depicts .
   ?depicts wdt:P31/wdt:P279* wd:Q178885 .
   
OPTIONAL {
  ?item wdt:P195 ?collection .
   ?collection rdfs:label ?collectionLabel .
   
FILTER(LANG(?collectionLabel) = "en")
} 
OPTIONAL {
  ?item wdt:P189 ?discoverySite .
   ?discoverySite wdt:P625 ?siteCoord
} 
OPTIONAL {
  ?item wdt:P18 ?image
} ?item rdfs:label ?itemLabel .
   
FILTER(LANG(?itemLabel) = "en") ?depicts rdfs:label ?depictsLabel .
   
FILTER(LANG(?depictsLabel) = "en")
}

Quagga has been developed by Odoma ↗ for Graphia ↗

Funded by the European Union (grant ID: 101188018 ↗)

and by the Swiss State Secretariat for Education, Research and Innovation (SERI).

Contact Github FAQ