Submissions for Polifonia MEETUPS KG

Description

The MEETUPS knowledge graph (Musical Meetups Knowledge Graph, MMKG) is a structured Linked Open Data resource developed in the EU-funded Polifonia project. It encodes evidence of historical encounters and collaborations between people in the European musical world (c. 1800–1945), extracted from tens of thousands of artist biographies using NLP and knowledge engineering. The graph models participants, places, dates, and purposes of musical meetups according to the Meetups Ontology, enabling rich queries about who met whom, where and why, for research, teaching and digital humanities applications via a SPARQL endpoint and web tools.

15 of 15 submissions
#108

Natural Language Question

Which places did Clara Schumann visit in her career?

SPARQL Query

Run Query 
PREFIX mtp: <http://w3id.org/polifonia/ontology/meetups-ontology#> 
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
SELECT DISTINCT ?resource ?placeLabel
WHERE { 
  VALUES ?subject { <http://dbpedia.org/resource/Clara_Schumann> } 
  ?s mtp:hasSubject ?subject ; mtp:hasType ?type . 
  FILTER (regex ( str (?type), str ("HM") ) ) . 
  ?s  mtp:hasPlace ?aPlaceIRI .
  ?aPlaceIRI mtp:hasEntity ?resource .  
  ?resource rdfs:label ?placeLabel . 
}
#188

Natural Language Question

Who are the people whose biographies appear in this knowledge graph?

Source

https://polifonia.kmi.open.ac.uk/meetups/queries.php

SPARQL Query

Run Query 
PREFIX mtp: <http://w3id.org/polifonia/ontology/meetups-ontology#> 
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX time: <http://www.w3.org/2006/time#>  

SELECT DISTINCT ?subjectID ?subjectLabel
WHERE {
    ?meetupID  mtp:hasSubject ?subjectID .
    ?subjectID rdfs:label ?subjectLabel
}
#315

Natural Language Question

What are the statistics of this knowledge graph (counts of meetups, excerpts, participants, subjects, places, and time expressions)?

SPARQL Query

Run Query 
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX fx: <http://sparql.xyz/facade-x/ns/>
PREFIX xyz: <http://sparql.xyz/facade-x/data/>
PREFIX mtp: <http://w3id.org/polifonia/ontology/meetups-ontology#>
PREFIX meetup: <http://w3id.org/polifonia/pilot/meetups/>
PREFIX core: <https://w3id.org/polifonia/ontology/core/>
PREFIX time: <http://www.w3.org/2006/time#>
PREFIX geo: <https://www.w3.org/2003/01/geo/wgs84_pos>

SELECT ?key ?value WHERE {
  {
    SELECT ?key(COUNT(*) AS ?value) {
      ?x a mtp:Meetup.
      BIND("Meetups" AS ?key)
    }
    GROUP BY ?key
  }
  UNION {
    SELECT ?key(COUNT(*) AS ?value) {
      ?x mtp:hasEvidenceText [].
      BIND("Excerpts" AS ?key)
    }
    GROUP BY ?key
  }
  UNION {
    SELECT ?key(COUNT(*) AS ?value) {
      ?x mtp:hasParticipant [].
      BIND("Persons mentioned" AS ?key)
    }
    GROUP BY ?key
  }
  UNION {
    SELECT ?key(COUNT(DISTINCT ?sub) AS ?value) {
      ?x mtp:hasSubject ?sub.
      BIND("Subjects" AS ?key)
    }
    GROUP BY ?key
  }
  UNION {
    SELECT ?key(COUNT(DISTINCT ?sub) AS ?value) {
      ?x mtp:hasPlace ?sub.
      BIND("Places mentions" AS ?key)
    }
    GROUP BY ?key
  }
  UNION {
    SELECT ?key(COUNT(*) AS ?value) {
      ?x mtp:happensAt ?time.
      BIND("Time expressions" AS ?key)
    }
    GROUP BY ?key
  }
}
#316

Natural Language Question

For meetups involving Niccolò Paganini, how is their time or duration recorded in the graph?

SPARQL Query

Run Query 
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX meetup: <http://w3id.org/polifonia/pilot/meetups/>
PREFIX mtp: <http://w3id.org/polifonia/ontology/meetups-ontology#>
PREFIX time: <http://www.w3.org/2006/time#>

SELECT * WHERE {
  VALUES ?subject {
    <http://dbpedia.org/resource/Niccolò_Paganini>
  }
  ?s mtp:hasSubject ?subject;
  mtp:happensAt ?time_expression.
  ?time_expression mtp:hasEvidenceText ?hasEvidenceTextTimeExpression;
  rdf:type ?typeTimeExpression.
  FILTER (?typeTimeExpression != mtp:TimeExpression).
  OPTIONAL {
    ?time_expression time:hasBeginning ?beginDate;
    time:hasEnd ?endDate.
  }.
}
#317

Natural Language Question

Which meetups involving Niccolò Paganini took place on or after January 1, 1900?

SPARQL Query

Run Query 
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX meetup: <http://w3id.org/polifonia/pilot/meetups/>
PREFIX mtp: <http://w3id.org/polifonia/ontology/meetups-ontology#>
PREFIX time: <http://www.w3.org/2006/time#>

SELECT * WHERE {
  VALUES ?subject {
    <http://dbpedia.org/resource/Niccolò_Paganini>
  }
  OPTIONAL {
    ?time_expression time:hasBeginning ?beginDate;
    time:hasEnd ?endDate;
    mtp:hasEvidenceText ?hasEvidenceTextTimeExpression;
    FILTER (?beginDate >= "1900-01-01"^^<http://www.w3.org/2001/XMLSchema#date>)
  }.
  ?s mtp:happensAt ?time_expression.
  ?s mtp:hasSubject ?subject.
}
ORDER BY ?beginDate
#318

Natural Language Question

How many biographies are in the MMKG?

SPARQL Query

Run Query 
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX mtp: <http://w3id.org/polifonia/ontology/meetups-ontology#>
PREFIX core: <https://w3id.org/polifonia/ontology/core/>

SELECT(COUNT(DISTINCT ?subject) AS ?total) WHERE {
  ?s mtp:hasType ?type.
  FILTER (regex(str(?type), str("HM"))).
  ?s mtp:hasSubject ?subject.
  ?subject rdf:type core:Person.
}
#319

Natural Language Question

How many historical meetups are in the graph?

SPARQL Query

Run Query 
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX mtp: <http://w3id.org/polifonia/ontology/meetups-ontology#>
PREFIX core: <https://w3id.org/polifonia/ontology/core/>

SELECT(COUNT(DISTINCT ?s) AS ?total) WHERE {
  ?s mtp:hasType ?type.
  FILTER (regex(str(?type), str("HM"))).
}
#320

Natural Language Question

How many distinct people are mentioned across all historical meetups in the graph?

SPARQL Query

Run Query 
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX mtp: <http://w3id.org/polifonia/ontology/meetups-ontology#>
PREFIX core: <https://w3id.org/polifonia/ontology/core/>

SELECT(COUNT(DISTINCT ?personIRI) AS ?total) WHERE {
  ?s mtp:hasType ?type.
  FILTER (regex(str(?type), str("HM"))).
  ?s mtp:hasParticipant ?participant.
  ?participant mtp:hasEntity ?personIRI.
}
#321

Natural Language Question

How many distinct places are mentioned in the meetup records?

SPARQL Query

Run Query 
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX mtp: <http://w3id.org/polifonia/ontology/meetups-ontology#>
PREFIX core: <https://w3id.org/polifonia/ontology/core/>

SELECT(COUNT(DISTINCT ?placeIRI) AS ?total) WHERE {
  ?s mtp:hasType ?type.
  FILTER (regex(str(?type), str("HM"))).
  ?s mtp:hasPlace ?place.
  ?place mtp:hasEntity ?placeIRI.
}
#322

Natural Language Question

How many temporal expressions are there in total?

SPARQL Query

Run Query 
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX mtp: <http://w3id.org/polifonia/ontology/meetups-ontology#>
PREFIX core: <https://w3id.org/polifonia/ontology/core/>

SELECT(COUNT(DISTINCT ?timeexpression) AS ?total) WHERE {
  ?s mtp:hasType ?type.
  FILTER (regex(str(?type), str("HM"))).
  ?s mtp:happensAt ?timeexpression.
  ?timeexpression rdf:type mtp:TimeExpression.
}
#323

Natural Language Question

Which places did Clara Schumann visit during her career?

SPARQL Query

Run Query 
PREFIX mtp: <http://w3id.org/polifonia/ontology/meetups-ontology#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT DISTINCT ?resource ?placeLabel WHERE {
  VALUES ?subject {
    <http://dbpedia.org/resource/Clara_Schumann>
  }
  ?s mtp:hasSubject ?subject;
  mtp:hasType ?type.
  FILTER (regex(str(?type), str("HM"))).
  ?s mtp:hasPlace ?aPlaceIRI.
  ?aPlaceIRI mtp:hasEntity ?resource.
  ?resource rdfs:label ?placeLabel.
}
#324

Natural Language Question

Which performers did Clara Schumann meet in her career and where did she meet them?

SPARQL Query

Run Query 
PREFIX mtp: <http://w3id.org/polifonia/ontology/meetups-ontology#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT DISTINCT ?resource ?placeLabel ?personIRI ?personLabel ?text WHERE {
  VALUES ?subject {
    <http://dbpedia.org/resource/Clara_Schumann>
  }
  ?s mtp:hasSubject ?subject;
  mtp:hasType ?type.
  FILTER (regex(str(?type), str("HM"))).
  ?s mtp:hasPlace ?aPlaceIRI.
  ?aPlaceIRI mtp:hasEntity ?resource.
  OPTIONAL {
    ?resource rdfs:label ?placeLabel
  }.
  ?s mtp:hasParticipant ?aParticipantIRI;
  mtp:hasEvidenceText ?text.
  ?aParticipantIRI rdf:type mtp:Participant;
  mtp:hasEntity ?personIRI.
  OPTIONAL {
    ?personIRI rdfs:label ?personLabel
  }.
}
ORDER BY ?s
#325

Natural Language Question

Why did Clara Schumann and Joseph Joachim meet?

SPARQL Query

Run Query 
PREFIX mtp: <http://w3id.org/polifonia/ontology/meetups-ontology#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT DISTINCT ?resource ?placeLabel ?personIRI ?personLabel ?text ?purposeLabel1 WHERE {
  VALUES ?subject {
    <http://dbpedia.org/resource/Clara_Schumann>
  }
  VALUES ?participant {
    <http://dbpedia.org/resource/Joseph_Joachim> <https://www.wikidata.org/wiki/Q159976>
  }
  ?s mtp:hasSubject ?subject;
  mtp:hasType ?type.
  FILTER (regex(str(?type), str("HM"))).
  ?s mtp:hasPlace ?aPlaceIRI.
  ?aPlaceIRI mtp:hasEntity ?resource.
  OPTIONAL {
    ?resource rdfs:label ?placeLabel
  }.
  ?s mtp:hasParticipant ?aParticipantIRI;
  mtp:hasEvidenceText ?text.
  ?aParticipantIRI rdf:type mtp:Participant;
  mtp:hasEntity ?personIRI.
  OPTIONAL {
    ?personIRI rdfs:label ?personLabel
  }.
  FILTER EXISTS {
    ?aParticipantIRI mtp:hasEntity ?participant
  }.
  ?s mtp:hasPurpose ?aPurposeIRI.
  ?aPurposeIRI rdf:type mtp:Purpose;
  mtp:hasAPurposeFirst ?purpose1.
  ?purpose1 rdfs:label ?purposeLabel1.
}
ORDER BY ?s
#326

Natural Language Question

Which other musicians were working at the same time as Clara Schumann?

SPARQL Query

Run Query 
PREFIX mtp: <http://w3id.org/polifonia/ontology/meetups-ontology#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT DISTINCT ?personIRI ?personLabel WHERE {
  VALUES ?subject {
    <http://dbpedia.org/resource/Clara_Schumann>
  }
  ?s mtp:hasSubject ?subject;
  mtp:hasType ?type.
  FILTER (regex(str(?type), str("HM"))).
  ?s mtp:hasParticipant ?aParticipantIRI;
  mtp:hasEvidenceText ?text.
  ?aParticipantIRI rdf:type mtp:Participant;
  mtp:hasEntity ?personIRI.
  OPTIONAL {
    ?personIRI rdfs:label ?personLabel
  }.
}
ORDER BY ?personLabel
#327

Natural Language Question

Who was in Clara Schumann's network?

SPARQL Query

Run Query 
PREFIX mtp: <http://w3id.org/polifonia/ontology/meetups-ontology#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT DISTINCT ?personIRI ?personLabel WHERE {
  VALUES ?subject {
    <http://dbpedia.org/resource/Clara_Schumann>
  }
  ?s mtp:hasSubject ?subject;
  mtp:hasParticipant ?aParticipantIRI;
  mtp:hasEvidenceText ?text.
  ?aParticipantIRI rdf:type mtp:Participant;
  mtp:hasEntity ?personIRI.
  OPTIONAL {
    ?personIRI rdfs:label ?personLabel
  }.
}
ORDER BY ?personLabel
Back to Browse
Odoma and Graphia logos

Quagga has been developed by Odoma ↗ for Graphia ↗

Funded by the European Union (grant ID: 101188018 ↗)

and by the Swiss State Secretariat for Education, Research and Innovation (SERI).

Contact Github FAQ