Submissions for DTL1000
Description
The metadata to the clean audio dataset of 1060 jazz recordings created in the Dig That Lick project: performances, sessions, recordings, musicians, bands and related discographic information. It includes a roughly euqal number of recordings from each decade of jazz; all the tracks have been manually segmented and have solo timestamps, instruments and soloists attached.
3 of 3 submissions
#247
Natural Language Question
For the Curtis Fuller session performing "Scrapple from the apple", list all solos with their start and end times, the soloist’s name and instrument, and the session date.
SPARQL Query
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX dtl: <http://www.DTL.org/schema/properties/>
PREFIX event: <http://purl.org/NET/c4dm/event.owl#>
PREFIX mo: <http://purl.org/ontology/mo/>
PREFIX tl: <http://purl.org/NET/c4dm/timeline.owl#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
SELECT ?startdate ?solostart ?soloend
?solo_instrument_label ?soloist_name
WHERE {
?performance rdf:type mo:Performance .
?performance dc:title "Scrapple from the apple" .
?session event:sub_event ?performance .
?session event:time ?date .
?date tl:at ?startdate .
?session mo:performer ?band .
?band foaf:name "Curtis Fuller" .
?performance event:sub_event ?solo .
?solo event:time ?solotime .
?solotime tl:beginsAt ?solostart .
?solotime tl:endsAt ?soloend .
?solo dtl:solo_instrument ?solo_instrument .
?solo_instrument dtl:dtl_inst_label
?solo_instrument_label .
?solo dtl:solo_performer ?soloperformer .
?soloperformer dtl:musician ?soloist .
?soloist foaf:name ?soloist_name .
} ORDER BY (?solostart)
#248
Natural Language Question
Which bands played or recorded the tune "Caravan," and when?
SPARQL Query
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX event: <http://purl.org/NET/c4dm/event.owl#>
PREFIX mo: <http://purl.org/ontology/mo/>
PREFIX tl: <http://purl.org/NET/c4dm/timeline.owl#>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
SELECT DISTINCT ?bandname ?startdate
WHERE {
?tune rdf:type mo:MusicalWork .
?tune dc:title "Caravan" .
?tune mo:performed_in ?performance .
?performance dc:title ?perft .
?session event:sub_event ?performance .
?session event:time ?date .
?date tl:at ?startdate .
?session mo:performer ?band .
?band foaf:name ?bandname .
}
ORDER BY (?startdate)
#249
Natural Language Question
Which releases have the given title and record count?
SPARQL Query
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX mo: <http://purl.org/ontology/mo/>
SELECT ?release
WHERE {
?release rdf:type mo:Release .
?release dc:title "%s" .
?release mo:record_count "%i" .
}
