Submissions for Culture Knowledge Graph
Description
large-scale semantic infrastructure developed within NFDI4Culture to interconnect heterogeneous cultural heritage and humanities research data — including musicology, art history, performance, archives, and audiovisual collections. It aggregates metadata from distributed repositories into a shared graph based on ontologies such as NFDIcore and the NFDI4Culture Ontology (CTO), enabling cross-collection discovery, SPARQL querying, interoperability, and AI-driven exploration of cultural data across institutions and domains.
2 of 2 submissions
#242
Natural Language Question
Show me sample resources from RISM Online related to the musicians Beethoven, Rossini, Liszt and Mendelssohn Bartholdy, from the same year that Ferdinand Gregorovius dealt with the musicians in his letters.
Source
SPARQL Query
PREFIX cto: <https://nfdi4culture.de/ontology/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX schema: <http://schema.org/>
PREFIX nfdicore: <https://nfdi.fiz-karlsruhe.de/ontology/>
PREFIX n4c: <https://nfdi4culture.de/id/>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX gnd: <https://d-nb.info/gnd/>
SELECT DISTINCT
?year
?musician
?letter
?letterID
# Just show one musical example source from RISM Online
(SAMPLE(?musicalSourceLabel) AS ?musicalSource)
(SAMPLE(?pattern) AS ?musicIncipitPattern)
(SAMPLE(?rismResource) AS ?rismID)
WHERE {
VALUES ?gnd { <https://d-nb.info/gnd/118573527> <http://d-nb.info/gnd/118573527> <https://d-nb.info/gnd/118580779> <http://d-nb.info/gnd/118580779> <http://d-nb.info/gnd/118602985> <https://d-nb.info/gnd/118602985> <https://d-nb.info/gnd/118508288> <http://d-nb.info/gnd/118508288> }
# cto:is referenced in
?letterID cto:CTO_0001006 n4c:E5378.
?letterID rdfs:label ?letterLabel ;
# cto:has related person/nfdicore:has external identifier
cto:CTO_0001009/nfdicore:NFDI_0001006 ?gnd ;
# cto:has creation date
cto:CTO_0001072 ?date .
bind(year(xsd:date(?date)) as ?year) .
# cto:is referenced in
?rismResource cto:CTO_0001006 n4c:E5313 .
# cto:has related person/nfdicore:has external identifier
?rismResource cto:CTO_0001009 ?person .
?person nfdicore:NFDI_0001006 ?gnd .
?rismResource rdfs:label ?rismLabel ;
# cto:has creation period
cto:CTO_0001073 ?tempCover ;
# cto:has incipit
cto:CTO_0001065 ?incipit .
# cto:has incipit pattern
?incipit cto:CTO_0001063 ?pattern .
?person rdfs:label ?musician .
# Filter for a musical source of the same year from RISM Online
FILTER(regex(str(?tempCover), str(?year)))
# Concat label of letters/musical sources with date
BIND(CONCAT(?letterLabel, " (", ?date, ")") AS ?letter)
BIND(CONCAT(?rismLabel, " (", ?tempCover, ")") AS ?musicalSourceLabel)
}
ORDER BY ?year
#243
Natural Language Question
Where and when was Yair Bacharach born, when did he die and where is he buried?
Source
SPARQL Query
PREFIX wdtn: <http://www.wikidata.org/prop/direct-normalized/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX schema: <http://schema.org/>
PREFIX n4c: <https://nfdi4culture.de/id/>
PREFIX cto: <https://nfdi4culture.de/ontology/>
PREFIX nfdicore: <https://nfdi.fiz-karlsruhe.de/ontology/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX bd: <http://www.bigdata.com/rdf#>
SELECT
?headstone
?headstoneLabel
#?headstoneLocation
#?wikidataIDheadstoneLocation
?wikidataIDheadstoneLocationLabel
?headstoneDate
?headstoneYear
?wikidataIDPerson
(SAMPLE(?wikidataIDPersonLabel) AS ?personLabel)
#?gender
?genderLabel
#?placeOfBirth
?placeOfBirthLabel
(SAMPLE(?dateOfBirth) AS ?birthDate)
(SAMPLE(?birthYear) AS ?yearOfBirth)
WHERE {
BIND(<https://d-nb.info/gnd/173368786> AS ?person)
#cto:is referenced in
?headstone cto:CTO_0001006 n4c:E6317 ;
# cto:has related person/nfdicore:has external identifier
cto:CTO_0001009/nfdicore:NFDI_0001006 ?person ;
rdfs:label ?headstoneLabel ;
# cto:has related location/nfdicore:has external identifier
cto:CTO_0001011/nfdicore:NFDI_0001006 ?headstoneLocation ;
# cto:has approximate period
cto:CTO_0001071 ?headstoneDate .
# a nfdicore:GND identifier
?person a nfdicore:NFDI_0001009 .
# a nfdicore:TGN identifier
?location a nfdicore:NFDI_0001055 .
FILTER(lang(?headstoneLabel) = 'en')
BIND(REPLACE(STR(?person), "^.*/", "") AS ?personGNDid)
BIND(REPLACE(STR(?headstoneLocation), "^.*/", "") AS ?headstoneLocationTGNid)
FILTER (datatype(?headstoneDate) = xsd:date)
bind(year(xsd:date(?headstoneDate)) as ?headstoneYear)
SERVICE <https://query.wikidata.org/sparql> {
?wikidataIDPerson wdt:P227 ?personGNDid .
OPTIONAL { ?wikidataIDPerson rdfs:label ?wikidataIDPersonLabel . FILTER(lang(?wikidataIDPersonLabel) = "en" || lang(?wikidataIDPersonLabel) = "mul") }
?wikidataIDheadstoneLocation wdt:P1667 ?headstoneLocationTGNid .
OPTIONAL { ?wikidataIDheadstoneLocation rdfs:label ?wikidataIDheadstoneLocationLabel . FILTER(LANG(?wikidataIDheadstoneLocationLabel) = "en") }
OPTIONAL {
?wikidataIDPerson wdt:P21 ?gender
OPTIONAL { ?gender rdfs:label ?genderLabel . FILTER(LANG(?genderLabel) = "en") }
}
OPTIONAL {
?wikidataIDPerson wdt:P19 ?placeOfBirth
OPTIONAL { ?placeOfBirth rdfs:label ?placeOfBirthLabel . FILTER(LANG(?placeOfBirthLabel) = "en") }
}
OPTIONAL {
?wikidataIDPerson wdt:P569 ?dateOfBirth
BIND(YEAR(?dateOfBirth) AS ?birthYear)
}
}
} ORDER BY ?headstoneDate
