Submissions for EHRI - KG
Description
The EHRI Knowledge Graph (EHRI-KG) is a Linked Open Data (LOD) representation of the EHRI Portal’s metadata about Holocaust-related archival sources. Developed to complement the EHRI Portal, it transforms archival descriptions—such as countries, institutions, collection records, and more—into a semantically enriched, interlinked graph.
13 of 13 submissions
#29
Natural Language Question
What is the average number of archival documents per institution by country of provenance?
Source
SPARQL Query
PREFIX db: <http://dbpedia.org/>
PREFIX dbp: <http://dbpedia.org/property/>
PREFIX rico: <https://www.ica.org/standards/RiC/ontology#>
PREFIX dbo: <http://dbpedia.org/ontology/>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX schema: <http://schema.org/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX ehri: <http://lod.ehri-project-test.eu/>
PREFIX ehri_institutions: <http://lod.ehri-project-test.eu/institutions/>
PREFIX ehri_units: <http://lod.ehri-project-test.eu/units/>
PREFIX ehri_countries: <http://lod.ehri-project-test.eu/countries/>
SELECT ?country (AVG(?totalRecordByInstitution) as ?meanByCountry) WHERE {
?country a rico:Place ;
rico:containsOrContained ?institution .
{
SELECT ?institution (COUNT(?record) as ?totalRecordByInstitution) WHERE {
?institution a rico:CorporateBody ;
rico:isOrWasHolderOf ?instantiation .
?instantiation a rico:Instantiation ;
rico:isInstantiationOf ?record .
?record a rico:Record .
} GROUP BY ?institution
}
} GROUP BY ?country
#30
Natural Language Question
What is the total number of archival records per institution for heritage institutions in Great Britain?
Source
SPARQL Query
PREFIX db: <http://dbpedia.org/>
PREFIX dbp: <http://dbpedia.org/property/>
PREFIX rico: <https://www.ica.org/standards/RiC/ontology#>
PREFIX dbo: <http://dbpedia.org/ontology/>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX schema: <http://schema.org/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX ehri: <http://lod.ehri-project-test.eu/ontology#>
PREFIX ehri_institutions: <http://lod.ehri-project-test.eu/institutions/>
PREFIX ehri_units: <http://lod.ehri-project-test.eu/units/>
PREFIX ehri_countries: <http://lod.ehri-project-test.eu/countries/>
SELECT ?institution (COUNT(?record) as ?totalRecords) WHERE {
ehri_countries:gb a ehri:Country ;
rico:isOrWasLocationOfAgent ?institution .
?record a ehri:Record ;
rico:title ?recordLabel ;
rico:hasOrHadHolder ?institution ;
} GROUP BY ?institution ORDER BY DESC(?totalRecords)
#121
Natural Language Question
Which archival institutions in the EHRI Knowledge Graph are located in Argentina, and what are their names?
Source
SPARQL Query
PREFIX db: <http://dbpedia.org/>
PREFIX dbp: <http://dbpedia.org/property/>
PREFIX rico: <https://www.ica.org/standards/RiC/ontology#>
PREFIX dbo: <http://dbpedia.org/ontology/>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX schema: <http://schema.org/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX ehri: <http://lod.ehri-project-test.eu/ontology#>
PREFIX ehri_institutions: <http://lod.ehri-project-test.eu/institutions/>
PREFIX ehri_units: <http://lod.ehri-project-test.eu/units/>
PREFIX ehri_countries: <http://lod.ehri-project-test.eu/countries/>
SELECT ?institution ?institutionLabel WHERE {
ehri_countries:ar a ehri:Country ;
rico:name ?countryLabel ;
rico:containsOrContained ?institution .
?institution rico:name ?institutionLabel .
}
#122
Natural Language Question
What contact details are available for archival institutions in Argentina in the EHRI Knowledge Graph, such as their addresses, postal codes, phone numbers, and email addresses?
Source
SPARQL Query
PREFIX db: <http://dbpedia.org/>
PREFIX dbp: <http://dbpedia.org/property/>
PREFIX rico: <https://www.ica.org/standards/RiC/ontology#>
PREFIX dbo: <http://dbpedia.org/ontology/>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX schema: <http://schema.org/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX ehri: <http://lod.ehri-project-test.eu/ontology#>
PREFIX ehri_institutions: <http://lod.ehri-project-test.eu/institutions/>
PREFIX ehri_units: <http://lod.ehri-project-test.eu/units/>
PREFIX ehri_countries: <http://lod.ehri-project-test.eu/countries/>
SELECT * WHERE {
ehri_countries:ar a ehri:Country ;
rico:name ?countryLabel ;
rico:isOrWasLocationOfAgent ?institution .
?institution a ehri:Institution ;
rico:name ?institutionLabel ;
rico:agentHasOrHadLocation ?instutionLocation .
?instutionLocation rico:hasOrHadPhysicalLocation ?physicalLocation .
?physicalLocation schema:telephone ?phone ;
schema:email ?email ;
rico:name ?address ;
schema:postalCode ?zipCode .
}
#123
Natural Language Question
Which countries are listed in the EHRI Knowledge Graph, and what are their names?
Source
SPARQL Query
PREFIX db: <http://dbpedia.org/>
PREFIX dbp: <http://dbpedia.org/property/>
PREFIX rico: <https://www.ica.org/standards/RiC/ontology#>
PREFIX dbo: <http://dbpedia.org/ontology/>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX schema: <http://schema.org/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX ehri: <http://lod.ehri-project-test.eu/ontology#>
PREFIX ehri_institutions: <http://lod.ehri-project-test.eu/institutions/>
PREFIX ehri_units: <http://lod.ehri-project-test.eu/units/>
PREFIX ehri_countries: <http://lod.ehri-project-test.eu/countries/>
SELECT ?country ?countryLabel WHERE {
?country a ehri:Country ;
rico:name ?countryLabel .
}
#124
Natural Language Question
Which archival record sets are held by the NIOD Instituut voor Oorlogs-, Holocaust- en Genocidestudies (https://lod.ehri-project-test.eu/institutions/nl-002896), and what are their titles?
Source
SPARQL Query
PREFIX db: <http://dbpedia.org/>
PREFIX db: <http://dbpedia.org/>
PREFIX dbp: <http://dbpedia.org/property/>
PREFIX rico: <https://www.ica.org/standards/RiC/ontology#>
PREFIX dbo: <http://dbpedia.org/ontology/>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX schema: <http://schema.org/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX ehri: <http://lod.ehri-project-test.eu/ontology#>
PREFIX ehri_institutions: <http://lod.ehri-project-test.eu/institutions/>
PREFIX ehri_units: <http://lod.ehri-project-test.eu/units/>
PREFIX ehri_countries: <http://lod.ehri-project-test.eu/countries/>
SELECT ?record ?recordLabel WHERE {
?record a ehri:RecordSet ;
rico:hasOrHadHolder ehri_institutions:nl-002896 ;
rico:title ?recordLabel .
}
#125
Natural Language Question
What are the summaries in Dutch for the archival records held by Kazerne Dossin?
Source
SPARQL Query
PREFIX db: <http://dbpedia.org/>
PREFIX dbp: <http://dbpedia.org/property/>
PREFIX rico: <https://www.ica.org/standards/RiC/ontology#>
PREFIX dbo: <http://dbpedia.org/ontology/>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX schema: <http://schema.org/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX ehri: <http://lod.ehri-project-test.eu/ontology#>
PREFIX ehri_institutions: <http://lod.ehri-project-test.eu/institutions/>
PREFIX ehri_units: <http://lod.ehri-project-test.eu/units/>
PREFIX ehri_countries: <http://lod.ehri-project-test.eu/countries/>
SELECT ?record ?recordLabel ?scopeAndContent WHERE {
?record a ehri:RecordSet ;
rico:hasOrHadHolder ehri_institutions:be-002157 ;
rico:title ?recordLabel ;
rico:scopeAndContent ?scopeAndContent .
FILTER(lang(?scopeAndContent) = "nl")
}
#126
Natural Language Question
Which archival record sets are about newspapers?
Source
SPARQL Query
PREFIX db: <http://dbpedia.org/>
PREFIX dbp: <http://dbpedia.org/property/>
PREFIX rico: <https://www.ica.org/standards/RiC/ontology#>
PREFIX dbo: <http://dbpedia.org/ontology/>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX schema: <http://schema.org/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX ehri: <http://lod.ehri-project-test.eu/ontology#>
PREFIX ehri_institutions: <http://lod.ehri-project-test.eu/institutions/>
PREFIX ehri_units: <http://lod.ehri-project-test.eu/units/>
PREFIX ehri_countries: <http://lod.ehri-project-test.eu/countries/>
PREFIX ehri_terms: <http://lod.ehri-project-test.eu/vocabularies/ehri-terms/>
SELECT ?record ?recordLabel WHERE {
?record a ehri:RecordSet ;
rico:title ?recordLabel ;
rico:hasOrHadSubject ehri_terms:1069 .
}
#127
Natural Language Question
How many archival records are held by institutions in Great Britain?
Source
SPARQL Query
PREFIX db: <http://dbpedia.org/>
PREFIX dbp: <http://dbpedia.org/property/>
PREFIX rico: <https://www.ica.org/standards/RiC/ontology#>
PREFIX dbo: <http://dbpedia.org/ontology/>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX schema: <http://schema.org/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX ehri: <http://lod.ehri-project-test.eu/ontology#>
PREFIX ehri_institutions: <http://lod.ehri-project-test.eu/institutions/>
PREFIX ehri_units: <http://lod.ehri-project-test.eu/units/>
PREFIX ehri_countries: <http://lod.ehri-project-test.eu/countries/>
SELECT (COUNT(?record) as ?totalRecords) WHERE {
ehri_countries:gb a ehri:Country ;
rico:isOrWasLocationOfAgent ?institution .
?record a ehri:RecordSet ;
rico:title ?recordLabel ;
rico:hasOrHadHolder ?institution ;
}
#129
Natural Language Question
What is the average number of records held by archival institutions in each country? Sort the results in descending order.
Source
SPARQL Query
PREFIX db: <http://dbpedia.org/>
PREFIX dbp: <http://dbpedia.org/property/>
PREFIX rico: <https://www.ica.org/standards/RiC/ontology#>
PREFIX dbo: <http://dbpedia.org/ontology/>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX schema: <http://schema.org/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX ehri: <http://lod.ehri-project-test.eu/ontology#>
PREFIX ehri_institutions: <http://lod.ehri-project-test.eu/institutions/>
PREFIX ehri_units: <http://lod.ehri-project-test.eu/units/>
PREFIX ehri_countries: <http://lod.ehri-project-test.eu/countries/>
SELECT ?country (AVG(?totalRecordByInstitution) as ?meanByCountry) WHERE {
?country a ehri:Country ;
rico:isOrWasLocationOfAgent ?institution .
{
SELECT ?institution (COUNT(?record) as ?totalRecordByInstitution) WHERE {
?record a ehri:RecordSet ;
rico:title ?recordLabel ;
rico:hasOrHadHolder ?institution .
?institution a ehri:Institution ;
} GROUP BY ?institution
}
} GROUP BY ?country
ORDER BY DESC(?meanByCountry)
#130
Natural Language Question
How many records from the CDEC (Centro di Documentazione Ebraica Contemporanea) are about people who are Holocaust survivors versus those who are not?
(Federated query against CDEC)
Source
SPARQL Query
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX fo: <http://www.w3.org/1999/XSL/Format#>
PREFIX db: <http://dbpedia.org/>
PREFIX dbp: <http://dbpedia.org/property/>
PREFIX rico: <https://www.ica.org/standards/RiC/ontology#>
PREFIX dbo: <http://dbpedia.org/ontology/>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX schema: <http://schema.org/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX ehri: <http://lod.ehri-project-test.eu/ontology#>
PREFIX ehri_institutions: <http://lod.ehri-project-test.eu/institutions/>
PREFIX ehri_units: <http://lod.ehri-project-test.eu/units/>
PREFIX ehri_countries: <http://lod.ehri-project-test.eu/countries/>
PREFIX bio-ext: <http://dati.cdec.it/lod/bio-ext/>
SELECT ?survivor (COUNT(?record) as ?recordCount) WHERE {
?record a ehri:RecordSet ;
rico:hasOrHadHolder ehri_institutions:it-002845 ;
rico:hasOrHadSubject ?personEHRI .
?personEHRI owl:sameAs ?person .
SERVICE <http://lod.xdams.org/sparql> {
?person a foaf:Person ;
bio-ext:shoahSurvivor ?survivor .
}
} GROUP BY ?survivor
#131
Natural Language Question
Which records from the CDEC (Jewish Contemporary Documentation Center) mention people who were deported to Auschwitz?
(Federated query against CDEC, http://lod.xdams.org/sparql)
Source
SPARQL Query
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX fo: <http://www.w3.org/1999/XSL/Format#>
PREFIX db: <http://dbpedia.org/>
PREFIX dbp: <http://dbpedia.org/property/>
PREFIX rico: <https://www.ica.org/standards/RiC/ontology#>
PREFIX dbo: <http://dbpedia.org/ontology/>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX schema: <http://schema.org/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX ehri: <http://lod.ehri-project-test.eu/ontology#>
PREFIX ehri_institutions: <http://lod.ehri-project-test.eu/institutions/>
PREFIX ehri_units: <http://lod.ehri-project-test.eu/units/>
PREFIX ehri_countries: <http://lod.ehri-project-test.eu/countries/>
PREFIX bio-ext: <http://dati.cdec.it/lod/bio-ext/>
PREFIX shoah: <http://dati.cdec.it/lod/shoah/>
SELECT ?record WHERE {
?record a ehri:RecordSet ;
rico:hasOrHadHolder ehri_institutions:it-002845 ;
rico:hasOrHadSubject ?personEHRI .
?personEHRI owl:sameAs ?person .
SERVICE <http://lod.xdams.org/sparql> {
?person a foaf:Person ;
shoah:persecution ?persecution .
?persecution shoah:toNaziCamp ?camp .
?camp rdfs:label "Auschwitz" .
}
}
#132
Natural Language Question
How many archival records are held in each country that has a population of less than 100,000?
(Federated query against DBpedia, https://dbpedia.org/sparql/)
Source
SPARQL Query
PREFIX rico: <https://www.ica.org/standards/RiC/ontology#>
PREFIX dbo: <http://dbpedia.org/ontology/>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX schema: <http://schema.org/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX ehri: <http://lod.ehri-project-test.eu/ontology#>
PREFIX ehri_institutions: <http://lod.ehri-project-test.eu/institutions/>
PREFIX ehri_units: <http://lod.ehri-project-test.eu/units/>
PREFIX ehri_countries: <http://lod.ehri-project-test.eu/countries/>
SELECT ?countryLabel (count(?record) as ?recordsCount) WHERE {
?country a ehri:Country ;
owl:sameAs ?dbCountry ;
rico:name ?countryLabel ;
rico:isOrWasLocationOfAgent ?institution .
?record a ehri:RecordSet ;
rico:title ?recordLabel ;
rico:hasOrHadHolder ?institution .
SERVICE <https://dbpedia.org/sparql/> {
?dbCountry dbo:populationTotal ?population .
}
FILTER (?population < 100000)
}
GROUP BY ?countryLabel
