Submissions for World Literature Knowledge Graph

Description

The World Literature Knowledge Graph (WL-KG) is a semantic resource containing 194,346 writers and 965,210 literary works, drawn from Wikidata, Open Library, and Goodreads. It is designed to address the underrepresentation of non-Western authors by integrating ethnic and biographical data with reader reception metrics under a unified ontology. Works and authors are modeled using FRBR, PROV-O, and DOLCE standards. The KG is accessible via SKATEBOARD, an interactive graph-based visualization platform, and supports use cases including literary discovery, humanities research, and recommender systems.

Learn more about this knowledge graph
Access the SPARQL endpoint
Download metadata

11 of 11 submissions

#208

Natural Language Question

How many book reviews does the knowledge graph contain?

#244

Natural Language Question

Who are the 20 most prolific non-anglophone writers in science fiction in the period 2000-2020?

SPARQL Query

Run Query

PREFIX urw: <http://purl.archive.org/urwriters#>
PREFIX urb: <http://purl.archive.org/urbooks#>
PREFIX prov: <http://www.w3.org/ns/prov#>
PREFIX frbr: <http://purl.org/vocab/frbr/core#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>

SELECT ?writerLabel ?countryLabel (COUNT(DISTINCT ?work) AS ?bookCount)
WHERE {
  # Identify writers with science fiction as an author-level topic
  ?writer a prov:Person .
  ?writer <http://www.w3.org/2000/01/rdf-schema#label> ?writerLabel .
  ?writer urw:authorTopic <http://purl.archive.org/urbooks#urb_subject_47> .

  # Country of birth is non-Anglophone
  ?writer urw:countryOfBirth ?cobIRI .
  ?cobIRI <http://www.w3.org/2000/01/rdf-schema#label> ?countryLabel .
  FILTER(?cobIRI NOT IN (
    <http://purl.archive.org/urwriters#USA>,
    <http://purl.archive.org/urwriters#GBR>,
    <http://purl.archive.org/urwriters#CAN>,
    <http://purl.archive.org/urwriters#AUS>,
    <http://purl.archive.org/urwriters#NZL>,
    <http://purl.archive.org/urwriters#IRL>
  ))

  # Also exclude if citizenship is Anglophone (catches naturalised writers)
  FILTER NOT EXISTS {
    ?writer urw:citizenship ?citIRI .
    FILTER(?citIRI IN (
      <http://purl.archive.org/urwriters#USA>,
      <http://purl.archive.org/urwriters#GBR>,
      <http://purl.archive.org/urwriters#CAN>,
      <http://purl.archive.org/urwriters#AUS>,
      <http://purl.archive.org/urwriters#NZL>,
      <http://purl.archive.org/urwriters#IRL>
    ))
  }

  # Works attributed to this writer, published 2000–2020
  ?writer prov:wasAttributedTo ?work .
  ?work a frbr:Expression .
  ?work urw:wasPublishedWhen ?yearIRI .
  BIND(xsd:integer(REPLACE(STR(?yearIRI), ".*#(\\d+)$", "$1")) AS ?year)
  FILTER(?year >= 2000 && ?year <= 2020)
}
GROUP BY ?writer ?writerLabel ?countryLabel
ORDER BY DESC(?bookCount)
LIMIT 20

#273

Natural Language Question

Which combinations of birth country and citizenship are the most common for authors who were born in an African country but hold European citizenship? Give me the top-10 combinations.

SPARQL Query

Run Query

SELECT ?birthLabel ?citizenshipLabel (COUNT(DISTINCT ?writer) AS ?writerCount) WHERE {
  ?writer a <http://www.w3.org/ns/prov#Person> .
  ?writer <http://purl.archive.org/urwriters#countryOfBirth> ?birthCountry .
  ?writer <http://purl.archive.org/urwriters#citizenship> ?citizenshipCountry .
  ?birthCountry <http://www.w3.org/2000/01/rdf-schema#label> ?birthLabel .
  ?citizenshipCountry <http://www.w3.org/2000/01/rdf-schema#label> ?citizenshipLabel .
  FILTER(?birthCountry != ?citizenshipCountry)

  # African countries (55)
  FILTER(?birthCountry IN (
    <http://purl.archive.org/urwriters#DZA>,<http://purl.archive.org/urwriters#AGO>,
    <http://purl.archive.org/urwriters#BEN>,<http://purl.archive.org/urwriters#BWA>,
    <http://purl.archive.org/urwriters#BFA>,<http://purl.archive.org/urwriters#BDI>,
    <http://purl.archive.org/urwriters#CPV>,<http://purl.archive.org/urwriters#CMR>,
    <http://purl.archive.org/urwriters#CAF>,<http://purl.archive.org/urwriters#TCD>,
    <http://purl.archive.org/urwriters#COM>,<http://purl.archive.org/urwriters#COG>,
    <http://purl.archive.org/urwriters#CIV>,<http://purl.archive.org/urwriters#COD>,
    <http://purl.archive.org/urwriters#DJI>,<http://purl.archive.org/urwriters#EGY>,
    <http://purl.archive.org/urwriters#GNQ>,<http://purl.archive.org/urwriters#ERI>,
    <http://purl.archive.org/urwriters#SWZ>,<http://purl.archive.org/urwriters#ETH>,
    <http://purl.archive.org/urwriters#GAB>,<http://purl.archive.org/urwriters#GMB>,
    <http://purl.archive.org/urwriters#GHA>,<http://purl.archive.org/urwriters#GIN>,
    <http://purl.archive.org/urwriters#GNB>,<http://purl.archive.org/urwriters#KEN>,
    <http://purl.archive.org/urwriters#LSO>,<http://purl.archive.org/urwriters#LBR>,
    <http://purl.archive.org/urwriters#LBY>,<http://purl.archive.org/urwriters#MDG>,
    <http://purl.archive.org/urwriters#MWI>,<http://purl.archive.org/urwriters#MLI>,
    <http://purl.archive.org/urwriters#MRT>,<http://purl.archive.org/urwriters#MUS>,
    <http://purl.archive.org/urwriters#MAR>,<http://purl.archive.org/urwriters#MOZ>,
    <http://purl.archive.org/urwriters#NAM>,<http://purl.archive.org/urwriters#NER>,
    <http://purl.archive.org/urwriters#NGA>,<http://purl.archive.org/urwriters#RWA>,
    <http://purl.archive.org/urwriters#STP>,<http://purl.archive.org/urwriters#SEN>,
    <http://purl.archive.org/urwriters#SYC>,<http://purl.archive.org/urwriters#SLE>,
    <http://purl.archive.org/urwriters#SOM>,<http://purl.archive.org/urwriters#ZAF>,
    <http://purl.archive.org/urwriters#SSD>,<http://purl.archive.org/urwriters#SDN>,
    <http://purl.archive.org/urwriters#TZA>,<http://purl.archive.org/urwriters#TGO>,
    <http://purl.archive.org/urwriters#TUN>,<http://purl.archive.org/urwriters#UGA>,
    <http://purl.archive.org/urwriters#ZMB>,<http://purl.archive.org/urwriters#ZWE>
  ))
  # European countries (46)
  FILTER(?citizenshipCountry IN (
    <http://purl.archive.org/urwriters#ALB>,<http://purl.archive.org/urwriters#AND>,
    <http://purl.archive.org/urwriters#AUT>,<http://purl.archive.org/urwriters#BLR>,
    <http://purl.archive.org/urwriters#BEL>,<http://purl.archive.org/urwriters#BIH>,
    <http://purl.archive.org/urwriters#BGR>,<http://purl.archive.org/urwriters#HRV>,
    <http://purl.archive.org/urwriters#CYP>,<http://purl.archive.org/urwriters#CZE>,
    <http://purl.archive.org/urwriters#DNK>,<http://purl.archive.org/urwriters#EST>,
    <http://purl.archive.org/urwriters#FIN>,<http://purl.archive.org/urwriters#FRA>,
    <http://purl.archive.org/urwriters#GEO>,<http://purl.archive.org/urwriters#DEU>,
    <http://purl.archive.org/urwriters#GRC>,<http://purl.archive.org/urwriters#HUN>,
    <http://purl.archive.org/urwriters#ISL>,<http://purl.archive.org/urwriters#IRL>,
    <http://purl.archive.org/urwriters#ITA>,<http://purl.archive.org/urwriters#LVA>,
    <http://purl.archive.org/urwriters#LIE>,<http://purl.archive.org/urwriters#LTU>,
      <http://purl.archive.org/urwriters#LUX>,<http://purl.archive.org/urwriters#MLT>,
    <http://purl.archive.org/urwriters#MDA>,<http://purl.archive.org/urwriters#MCO>,
    <http://purl.archive.org/urwriters#MNE>,<http://purl.archive.org/urwriters#NLD>,
    <http://purl.archive.org/urwriters#MKD>,<http://purl.archive.org/urwriters#NOR>,
    <http://purl.archive.org/urwriters#POL>,<http://purl.archive.org/urwriters#PRT>,
    <http://purl.archive.org/urwriters#ROU>,<http://purl.archive.org/urwriters#RUS>,
    <http://purl.archive.org/urwriters#SMR>,<http://purl.archive.org/urwriters#SRB>,
    <http://purl.archive.org/urwriters#SVK>,<http://purl.archive.org/urwriters#SVN>,
    <http://purl.archive.org/urwriters#ESP>,<http://purl.archive.org/urwriters#SWE>,
    <http://purl.archive.org/urwriters#CHE>,<http://purl.archive.org/urwriters#UKR>,
    <http://purl.archive.org/urwriters#GBR>,<http://purl.archive.org/urwriters#VAT>
  ))
}
GROUP BY ?birthLabel ?citizenshipLabel
ORDER BY DESC(?writerCount)

#274

Natural Language Question

What about: How do Western-born and non-Western–born authors compare in terms of how many authors there are, their total number of works, and their average works per author?

SPARQL Query

Run Query

SELECT ?region (COUNT(DISTINCT ?writer) AS ?authorCount)
       (SUM(?workCount) AS ?totalWorks)
       (AVG(?workCount) AS ?avgWorks)
WHERE {
  {
    SELECT ?writer (COUNT(?work) AS ?workCount) WHERE {
      ?writer a <http://www.w3.org/ns/prov#Person> .
      ?writer <http://www.w3.org/ns/prov#wasAttributedTo> ?work .
    }
    GROUP BY ?writer
  }
  ?writer <http://purl.archive.org/urwriters#countryOfBirth> ?birthCountry .
  BIND(IF(?birthCountry IN (
    <http://purl.archive.org/urwriters#USA>,<http://purl.archive.org/urwriters#CAN>,
    <http://purl.archive.org/urwriters#GBR>,<http://purl.archive.org/urwriters#IRL>,
    <http://purl.archive.org/urwriters#FRA>,<http://purl.archive.org/urwriters#DEU>,
    <http://purl.archive.org/urwriters#ITA>,<http://purl.archive.org/urwriters#ESP>,
    <http://purl.archive.org/urwriters#PRT>,<http://purl.archive.org/urwriters#NLD>,
    <http://purl.archive.org/urwriters#BEL>,<http://purl.archive.org/urwriters#CHE>,
    <http://purl.archive.org/urwriters#AUT>,<http://purl.archive.org/urwriters#DNK>,
    <http://purl.archive.org/urwriters#SWE>,<http://purl.archive.org/urwriters#NOR>,
    <http://purl.archive.org/urwriters#FIN>,<http://purl.archive.org/urwriters#ISL>,
    <http://purl.archive.org/urwriters#GRC>,<http://purl.archive.org/urwriters#LUX>,
    <http://purl.archive.org/urwriters#AUS>,<http://purl.archive.org/urwriters#NZL>,
    <http://purl.archive.org/urwriters#MLT>,<http://purl.archive.org/urwriters#CYP>),
    "Western", "Global South") AS ?region)
}
GROUP BY ?region

#281

Natural Language Question

How many Polish writers or poets have received the Nobel Prize?

#282

Natural Language Question

How many Polish writers or poets have received the Noble Prize in Literature?

#283

Natural Language Question

Which science fiction writers born in Poland published works between 2000 and 2020?

SPARQL Query

Run Query

PREFIX urw: <http://purl.archive.org/urwriters#>
PREFIX prov: <http://www.w3.org/ns/prov#>
PREFIX frbr: <http://purl.org/vocab/frbr/core#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT DISTINCT ?writerLabel
WHERE {
  ?writer a prov:Person ;
          rdfs:label ?writerLabel ;
          urw:authorTopic <http://purl.archive.org/urbooks#urb_subject_47> ;
          urw:countryOfBirth <http://purl.archive.org/urwriters#POL> ;
          prov:wasAttributedTo ?work .

  ?work a frbr:Expression ;
        urw:wasPublishedWhen ?yearIRI .

  BIND(xsd:integer(REPLACE(STR(?yearIRI), ".*#(\\d+)$", "$1")) AS ?year)

  FILTER(?year >= 2000 && ?year <= 2020)
}
ORDER BY ?writerLabel

#286

Natural Language Question

Which Polish-born writers have the largest number of works in the World Literature Knowledge Graph? Show the top 20

SPARQL Query

Run Query

PREFIX urw: <http://purl.archive.org/urwriters#>
PREFIX prov: <http://www.w3.org/ns/prov#>
PREFIX frbr: <http://purl.org/vocab/frbr/core#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT ?writer ?writerLabel (COUNT(DISTINCT ?work) AS ?workCount)
WHERE {
  ?writer a prov:Person ;
          rdfs:label ?writerLabel ;
          urw:countryOfBirth urw:POL ;
          prov:wasAttributedTo ?work .

  ?work a frbr:Expression .
}
GROUP BY ?writer ?writerLabel
ORDER BY DESC(?workCount)
LIMIT 20

#287

Natural Language Question

Which Polish-born writers have the largest number of works in the World Literature Knowledge Graph? Show the top 20.

SPARQL Query

Run Query

PREFIX urw: <http://purl.archive.org/urwriters#>
PREFIX prov: <http://www.w3.org/ns/prov#>
PREFIX frbr: <http://purl.org/vocab/frbr/core#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT ?writer ?writerLabel (COUNT(DISTINCT ?work) AS ?workCount)
WHERE {
  ?writer a prov:Person ;
          rdfs:label ?writerLabel ;
          urw:countryOfBirth urw:POL ;
          prov:wasAttributedTo ?work .

  ?work a frbr:Expression .
}
GROUP BY ?writer ?writerLabel
ORDER BY DESC(?workCount)
LIMIT 20

#288

Natural Language Question

Which Polish-born writers are associated with the largest number of distinct literary topics? Show the top 20.

SPARQL Query

Run Query

PREFIX urw: <http://purl.archive.org/urwriters#>
PREFIX prov: <http://www.w3.org/ns/prov#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT ?writer ?writerLabel
       (COUNT(DISTINCT ?topic) AS ?topicCount)
WHERE {
  ?writer a prov:Person ;
          rdfs:label ?writerLabel ;
          urw:countryOfBirth urw:POL ;
          urw:authorTopic ?topic .
}
GROUP BY ?writer ?writerLabel
ORDER BY DESC(?topicCount)
LIMIT 20

#289

Natural Language Question

Which literary topics are associated with the largest number of Polish-born writers? Show the top 20.

SPARQL Query

Run Query

PREFIX urw: <http://purl.archive.org/urwriters#>
PREFIX prov: <http://www.w3.org/ns/prov#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT ?topic ?topicLabel
       (COUNT(DISTINCT ?writer) AS ?writerCount)
WHERE {
  ?writer a prov:Person ;
          urw:countryOfBirth urw:POL ;
          urw:authorTopic ?topic .

  OPTIONAL {
    ?topic rdfs:label ?topicLabel .
  }
}
GROUP BY ?topic ?topicLabel
ORDER BY DESC(?writerCount)
LIMIT 20

Quagga has been developed by Odoma ↗ for Graphia ↗

Funded by the European Union (grant ID: 101188018 ↗)

and by the Swiss State Secretariat for Education, Research and Innovation (SERI).

Contact Github FAQ