Submissions for ARIADNE (Advanced Research Infrastructure for Archaeological Dataset Networking in Europe)
Description
The ARIADNE Research Infrastructure AISBL (ARIADNE RI) is a not-for-profit association that continues the work of ARIADNEplus (2018-22) and the previous ARIADNE Integrating Activity (2012-16). These projects established a Linked Open Data triplestore, also searchable via a portal interface, providing access to over 4m rich data resources. Encompassing the archaeology and heritage of 4 continents and over 40 countries, resources range from the archaeology of the earliest hominids to the present day. Data is modelled using the CIDOC CRM-compatible ARIADNE Catalogue Ontology (AO-Cat) and stored as RDF in a GraphDB triplestore, which can be queried via a public SPARQL endpoint.
3 of 3 submissions
#233
Natural Language Question
Which records in ARIADNE refer to coins, and what is their spatial and temporal coverage?
SPARQL Query
# Query adapted from script for ARIADNE data analysis
# By Petr Pajdla
# 2024-09-20 in Brno
# For atRium training school, https://www.aiscr.cz/atRium
# Identify all ARIADNE records for coins, with their spatial and temporal coverage (where available)
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX aat: <http://vocab.getty.edu/aat/>
SELECT ?ae ?pn ?lat ?lon ?from ?to WHERE {
# artefacts only
?ae aocat:has_ARIADNE_subject ?s .
?s rdfs:label 'Artefact'@en .
# match only coins
?ae aocat:has_derived_subject aat:300037222 .
# spatial coverage
OPTIONAL {?ae aocat:has_spatial_coverage ?sc}
OPTIONAL {?sc aocat:has_place_name ?pn}
OPTIONAL {?sc aocat:has_latitude ?lat}
OPTIONAL {?sc aocat:has_longitude ?lon}
# temporal coverage
OPTIONAL {?ae aocat:has_temporal_coverage ?tc}
OPTIONAL {?tc aocat:from ?from}
OPTIONAL {?tc aocat:until ?to}
}
#234
Natural Language Question
What ARIADNE subject types are available?
SPARQL Query
# Identify all ARIADNE subjects
PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
SELECT DISTINCT ?as ?label
WHERE {
?s aocat:has_ARIADNE_subject ?as .
?as rdfs:label ?label .
}
#235
Natural Language Question
Which ARIADNE resources are associated with the Tudor period in England, and what subject areas do they refer to?
SPARQL Query
# Identify all records relating to a particular PeriodO period, with their title and associated AAT subjects
PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
SELECT ?s ?title ?aat WHERE {
?s aocat:has_title ?title .
?s aocat:has_temporal_coverage ?tc .
# Example: Tudor period, according to Historic England:
?tc aocat:has_period <http://n2t.net/ark:/99152/p0kh9ds7jvs> .
OPTIONAL {?s aocat:has_derived_subject ?aat}
}
