Submissions for Europeana

Description

Europeana is the EU's cultural heritage platform. It contains metadata about more than 50 million digitised cultural heritage items (from books and paintings to 3D objects and audiovisual material), contributed by more than 3,700 institutions.

Learn more about this knowledge graph
Access the SPARQL endpoint
Download metadata

17 of 17 submissions

#32

Natural Language Question

List only organisations that are aggregators

Source

https://github.com/europeana/sparql-ui/blob/master/europeana/query-samples.json

SPARQL Query

Run Query

PREFIX edm: <http://www.europeana.eu/schemas/edm/>

SELECT DISTINCT ?Aggregator
WHERE {  ?Aggregation edm:provider ?Aggregator}

#63

Natural Language Question

what is the most common licence used in the collection

#64

Natural Language Question

what are the uniforms used by the italian army between 1861 and 1914?

#65

Natural Language Question

What is the cultural heritage institution from Poland with the biggest number of objects

#67

Natural Language Question

What are all the universities in germany?

#68

Natural Language Question

How many Italian institutions contributed to Europeana?

#74

Natural Language Question

Which knowledge graphs contain data about anthropology of the body?

#76

Natural Language Question

Which knowledge graphs contain data about anthropology of the body?

#80

Natural Language Question

Which knowledge graphs contain data about anthropology of the body?

SPARQL Query

Run Query

PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX edm: <http://www.europeana.eu/schemas/edm/>

SELECT ?item ?title ?description WHERE {
  ?item dc:subject ?subject .
  ?item dc:title ?title .
  OPTIONAL { ?item dc:description ?description . }
  FILTER (CONTAINS(LCASE(STR(?subject)), "anthropology") ||
          CONTAINS(LCASE(STR(?subject)), "body"))
}
LIMIT 50

#83

Natural Language Question

Which drawings are linked to Vincent van Gogh?

#87

Natural Language Question

What is the cultural heritage institution from France with the biggest number of objects, and how many?

SPARQL Query

Run Query

PREFIX edm: <http://www.europeana.eu/schemas/edm/>
PREFIX ore: <http://www.openarchives.org/ore/terms/>

SELECT ?provider (COUNT(?cho) as ?objectCount)
WHERE {
  ?aggregation a ore:Aggregation .
  ?aggregation edm:aggregatedCHO ?cho .
  ?aggregation edm:dataProvider ?provider .
  
  FILTER(regex(str(?provider), "France|français|fr", "i"))
}
GROUP BY ?provider
ORDER BY DESC(?objectCount)
LIMIT 1

#207

Natural Language Question

List Spanish periodicals by year

Source

https://api.europeana.eu/console/sparql/

SPARQL Query

Run Query

#List Spanish Periodicals by Year
SELECT ?date (count(*) as ?count)  {
  ?proxy dc:type 'info:eu-repo/semantics/article'.
  OPTIONAL { ?proxy dcterms:issued ?issued }
  OPTIONAL { ?proxy dc:date        ?dcdate }
  bind (xsd:integer(substr(coalesce(?issued,?dcdate),1,4)) as ?date)
}
GROUP BY ?date HAVING (?count>1)
ORDER BY ?date

#209

Natural Language Question

How many female-only exhibitions were organized in European museums and galleries from 1950 to 2000?

#236

Natural Language Question

Which countries have shared the most stuff with Europeana? Show me the top 10.

Source

https://github.com/europeana/sparql-ui

SPARQL Query

Run Query

PREFIX edm: <http://www.europeana.eu/schemas/edm/>

SELECT ?Country (COUNT(*) AS ?count)
WHERE {
  ?Aggregation edm:aggregatedCHO ?ProvidedCHO ;
               edm:country ?Country .
}
GROUP BY ?Country
ORDER BY DESC(?count)
LIMIT 10

#237

Natural Language Question

What free audio recordings can I listen to? Give me the first 100 results.

Source

https://github.com/europeana/sparql-ui/

SPARQL Query

Run Query

PREFIX edm: <http://www.europeana.eu/schemas/edm/>
PREFIX ore: <http://www.openarchives.org/ore/terms/>

SELECT DISTINCT ?ProvidedCHO ?WebResource
WHERE {
  ?Aggregation edm:rights ?Rights ;
               edm:isShownBy|edm:hasView ?WebResource ;
               edm:aggregatedCHO ?ProvidedCHO .
  ?Proxy ore:proxyIn ?Aggregation ;
         edm:type "SOUND" .
  FILTER (?Rights IN ( <http://creativecommons.org/publicdomain/mark/1.0/>
                     , <http://creativecommons.org/publicdomain/zero/1.0/>
                     , <http://creativecommons.org/licenses/by/1.0/>
                     , <http://creativecommons.org/licenses/by-sa/1.0/> ))
}
LIMIT 100

#238

Natural Language Question

Are there any artworks by Rembrandt?

Source

https://github.com/europeana/sparql-ui/

SPARQL Query

Run Query

PREFIX dc:  <http://purl.org/dc/elements/1.1/>
PREFIX ore: <http://www.openarchives.org/ore/terms/>

SELECT DISTINCT ?ProvidedCHO ?Creator
WHERE {
  ?Proxy dc:creator ?Creator ;
         ore:proxyFor ?ProvidedCHO .
  FILTER (regex(str(?Creator), "Rembrandt", "i"))
}
LIMIT 20

#239

Natural Language Question

I'd like to find pictures I can reuse for free — public domain or Creative Commons is fine.

Source

https://github.com/europeana/sparql-ui/

SPARQL Query

Run Query

PREFIX edm: <http://www.europeana.eu/schemas/edm/>
PREFIX ore: <http://www.openarchives.org/ore/terms/>

SELECT DISTINCT ?ProvidedCHO ?WebResource ?Rights
WHERE {
  ?Aggregation edm:rights ?Rights ;
               edm:isShownBy ?WebResource ;
               edm:aggregatedCHO ?ProvidedCHO .
  ?Proxy ore:proxyIn ?Aggregation ;
         edm:type "IMAGE" .
  FILTER (?Rights IN ( <http://creativecommons.org/publicdomain/mark/1.0/>
                     , <http://creativecommons.org/publicdomain/zero/1.0/>
                     , <http://creativecommons.org/licenses/by/1.0/>
                     , <http://creativecommons.org/licenses/by-sa/1.0/> ))
}
LIMIT 25

Quagga has been developed by Odoma ↗ for Graphia ↗

Funded by the European Union (grant ID: 101188018 ↗)

and by the Swiss State Secretariat for Education, Research and Innovation (SERI).

Contact Github FAQ