Submissions for Nomisma
Description
Nomisma knowledge graph is a Linked Open Data (LOD) resource developed by the American Numismatic Society (ANS) in collaboration with an international community of scholars. It provides stable URIs and a formal RDF ontology for numismatic concepts—such as coins, typologies, mints, and hoards—enabling structured representation of numismatic information and interlinking with external datasets. This knowledge graph supports semantic integration, SPARQL querying, and bulk downloads in multiple RDF serializations, facilitating research, interoperability, and reuse of numismatic data across digital projects and collections.
7 of 7 submissions
#109
Natural Language Question
Who are the Roman emperors contained in the knowledge graph? List them all by their English name/label.
SPARQL Query
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX nm: <http://nomisma.org/id/>
PREFIX nmo: <http://nomisma.org/ontology#>
PREFIX org: <http://www.w3.org/ns/org#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
SELECT ?uri ?label WHERE {
?uri a foaf:Person ;
skos:prefLabel ?label ;
org:hasMembership ?membership .
?membership org:role nm:roman_emperor .
FILTER(langMatches(lang(?label), "EN"))
}
#110
Natural Language Question
What is the average weight of Augustan Denarii?
Source
SPARQL Query
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX nm: <http://nomisma.org/id/>
PREFIX nmo: <http://nomisma.org/ontology#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
SELECT (AVG(xsd:decimal(?weight)) AS ?average) WHERE {
?type nmo:hasAuthority nm:augustus ;
nmo:hasDenomination nm:denarius ;
dcterms:source nm:ric.
?coin nmo:hasTypeSeriesItem ?type .
?coin nmo:hasWeight ?weight
}
#116
Natural Language Question
What are the weights of all denarius coins issued under Augustus in the Roman Imperial Coinage, considering only coins for which the weight is recorded?
Source
SPARQL Query
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX nm: <http://nomisma.org/id/>
PREFIX nmo: <http://nomisma.org/ontology#>
SELECT ?type ?weight WHERE {
?type nmo:hasAuthority nm:augustus ;
nmo:hasDenomination nm:denarius ;
dcterms:source nm:ric.
?coin nmo:hasTypeSeriesItem ?type .
?coin nmo:hasWeight ?weight
}
#117
Natural Language Question
Which coins belong to the Roman Imperial Coinage types Augustus 1A and Augustus 1B, and what information is available for each of them, such as their weight, diameter, die axis, the collection they come from, and any available images of the coin, obverse, and reverse?
SPARQL Query
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX nm: <http://nomisma.org/id/>
PREFIX nmo: <http://nomisma.org/ontology#>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
SELECT ?object ?type ?diameter ?weight ?axis ?type ?collection ?obvThumb ?revThumb ?obvRef ?revRef ?comThumb ?comRef WHERE {
{?object nmo:hasTypeSeriesItem <http://numismatics.org/ocre/id/ric.1(2).aug.1A> }
UNION { ?object nmo:hasTypeSeriesItem <http://numismatics.org/ocre/id/ric.1(2).aug.1B> }
?object rdf:type nmo:NumismaticObject .
OPTIONAL { ?object nmo:hasWeight ?weight }
OPTIONAL { ?object nmo:hasDiameter ?diameter }
OPTIONAL { ?object nmo:hasAxis ?axis }
OPTIONAL { ?object dcterms:identifier ?identifier }
OPTIONAL { ?object nmo:hasCollection ?colUri .
?colUri skos:prefLabel ?collection FILTER(langMatches(lang(?collection), "EN"))}
OPTIONAL { ?object foaf:thumbnail ?comThumb }
OPTIONAL { ?object foaf:depiction ?comRef }
OPTIONAL { ?object nmo:hasObverse ?obverse .
?obverse foaf:thumbnail ?obvThumb }
OPTIONAL { ?object nmo:hasObverse ?obverse .
?obverse foaf:depiction ?obvRef }
OPTIONAL { ?object nmo:hasReverse ?reverse .
?reverse foaf:thumbnail ?revThumb }
OPTIONAL { ?object nmo:hasReverse ?reverse .
?reverse foaf:depiction ?revRef }
}
#118
Natural Language Question
What is the average diameter of the coins classified as *RIC Augustus 1A*, based on the recorded measurements?
Source
SPARQL Query
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX nm: <http://nomisma.org/id/>
PREFIX nmo: <http://nomisma.org/ontology#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
SELECT (AVG(xsd:decimal(?diameter)) AS ?average) WHERE {
?object nmo:hasTypeSeriesItem <http://numismatics.org/ocre/id/ric.1(2).aug.1A> ;
nmo:hasDiameter ?diameter
}
#119
Natural Language Question
Where have coins of RIC Augustus 1A been found, either as individual finds or as part of hoards, and what locations are recorded for these finds (including place names and coordinates)?
Source
SPARQL Query
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX dcmitype: <http://purl.org/dc/dcmitype/>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX nm: <http://nomisma.org/id/>
PREFIX nmo: <http://nomisma.org/ontology#>
PREFIX geo: <http://www.w3.org/2003/01/geo/wgs84_pos#>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX crm: <http://www.cidoc-crm.org/cidoc-crm/>
SELECT ?object ?title ?findspot ?placeName ?hoard ?hoardLabel ?lat ?long ?type ?burial WHERE {
{ ?object a nmo:NumismaticObject ;
nmo:hasTypeSeriesItem <http://numismatics.org/ocre/id/ric.1(2).aug.1A>}
UNION { ?broader skos:broader+ <http://numismatics.org/ocre/id/ric.1(2).aug.1A> .
?object nmo:hasTypeSeriesItem ?broader ;
a nmo:NumismaticObject }
UNION { ?contents a dcmitype:Collection ;
nmo:hasTypeSeriesItem <http://numismatics.org/ocre/id/ric.1(2).aug.1A> .
?object dcterms:tableOfContents ?contents }
?object dcterms:title|skos:prefLabel ?title .
{ ?object nmo:hasFindspot/crm:P7_took_place_at/crm:P89_falls_within ?findspot }
UNION { ?object dcterms:isPartOf ?hoard .
?hoard a nmo:Hoard ;
skos:prefLabel ?hoardLabel ;
nmo:hasFindspot/crm:P7_took_place_at/crm:P89_falls_within ?findspot .
OPTIONAL {?hoard nmo:hasClosingDate ?burial . FILTER isLiteral(?burial)}
OPTIONAL {?hoard nmo:hasClosingDate ?closing .
?closing nmo:hasEndDate ?burial}}
?findspot rdfs:label ?placeName ;
geo:location ?loc .
?loc geo:lat ?lat ;
geo:long ?long .
OPTIONAL { ?object rdf:type ?type FILTER (?type != skos:Concept)}
OPTIONAL { ?object nmo:hasClosingDate ?burial . FILTER isLiteral(?burial) }}
#120
Natural Language Question
Which coins have been found in Northamptonshire, England (http://www.wikidata.org/entity/Q23115), including finds from places within the county, and in what chronological order were they issued?
Source
SPARQL Query
PREFIX crm: <http://www.cidoc-crm.org/cidoc-crm/>
PREFIX dcmitype: <http://purl.org/dc/dcmitype/>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX geo: <http://www.w3.org/2003/01/geo/wgs84_pos#>
PREFIX nm: <http://nomisma.org/id/>
PREFIX nmo: <http://nomisma.org/ontology#>
PREFIX org: <http://www.w3.org/ns/org#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
SELECT ?coin ?type ?date ?place WHERE {
?coin nmo:hasFindspot/crm:P7_took_place_at/crm:P89_falls_within ?place ;
nmo:hasTypeSeriesItem ?type ;
a nmo:NumismaticObject .
?place crm:P89_falls_within+ <http://www.wikidata.org/entity/Q23115> .
?type nmo:hasEndDate ?date .
} ORDER BY ASC(?date)
